how to use grep without change the output order - grep

Question

I have two files (LIST.txt and FILE1.txt). I'm trying to use the script grep to obtain an output in the same order of LIST.txt
LIST.txt
rs201196551
rs8071824
rs74620303
FILE1.txt
rs201196551 red
rs74620303 blue
rs9000000 pink
rs8071824 purple
I used this code: grep -wFf LIST.txt FILE1.txt > OUTPUT.txt
And I obtained this output:
rs201196551 red
rs74620303 blue
rs8071824 purple
But actually I expect this output:
rs201196551 red
rs8071824 purple
rs74620303 blue
(in the same order of LIST.txt).

Answer 1

I don't think you can change the output order of grep without additional tools. However, here is an awk that buffers the output in the order of the list file:
$ awk '
NR==FNR { # process list file
a[$0]=++c # store first word in a hash
next # process next list item
}
{ # process file1
for(i in a) # for each list item
if($1==i) { # see if it is the first word
b[a[i]]=b[a[i]] (b[a[i]]==""?"":ORS) $0 # store to output buffer
next # no more candidates after match
}
}
END { # in the end
for(i=1;i<=c;i++) # start outputing
if(b[i]!="") # skip empties
print b[i]
}' list file1
Output:
rs201196551 red
rs8071824 purple
rs74620303 blue
Update: From the comments, thanks #Sundeep:
$ awk '
NR==FNR { # lets hash the haystack instead ie. file1
a[$1]=$0
next
}
($0 in a) { # now read the needles from the list and lookup from a
print a[$0]
}' file1 list
Output:
rs201196551 red
rs8071824 purple
rs74620303 blue
However, if there are identical entries (of $1) in the file1, they will be lost (due to a[$1]=$0). Last entry in the file will remain.