How to delete the whole directory which is not empty? - erlang

Question

I want to clean the temporary for collecting resource.
The file module only has del_dir/1 which require the directory is empty. But there is not function the get the all files in the directory (with absolute path")
The source code is as follows, how to correct it?
delete_path(X)->
{ok,List} = file:list_dir_all(X), %% <--- return value has no absolute path here
lager:debug("_229:~n\t~p",[List]),
lists:map(fun(X)->
lager:debug("_231:~n\t~p",[X]),
ok = file:delete(X)
end,List),
ok = file:del_dir(X),
ok.

Answer 1

You can delete a directory via console command using os:cmd, though it's a rough approach. For unix-like OS it will be:
os:cmd("rm -Rf " ++ DirPath).
If you want to delete a non-empty directory using appropriate erlang functions you have to do it recursively. The following example from here shows how to do it:
-module(directory).
-export([del_dir/1]).
del_dir(Dir) ->
lists:foreach(fun(D) ->
ok = file:del_dir(D)
end, del_all_files([Dir], [])).
del_all_files([], EmptyDirs) ->
EmptyDirs;
del_all_files([Dir | T], EmptyDirs) ->
{ok, FilesInDir} = file:list_dir(Dir),
{Files, Dirs} = lists:foldl(fun(F, {Fs, Ds}) ->
Path = Dir ++ "/" ++ F,
case filelib:is_dir(Path) of
true ->
{Fs, [Path | Ds]};
false ->
{[Path | Fs], Ds}
end
end, {[],[]}, FilesInDir),
lists:foreach(fun(F) ->
ok = file:delete(F)
end, Files),
del_all_files(T ++ Dirs, [Dir | EmptyDirs]).

Answer 2

This is now possible with the latest version of Erlang/OTP (unreleased, yet), using the file:del_dir/2 API.
Available options:
recursive: recursively delete the contents of a directory before deleting the directory itself
force: ignore errors when accessing or deleting files or directories
keeptop: the top-most directory is not deleted
Source: https://github.com/erlang/otp/pull/2565

Answer 3

A different approach in Erlang (the only real reason for using is to maintain platform independence):
-spec rm_rf(file:filename()) -> ok.
rm_rf(Dir) ->
Paths = filelib:wildcard(Dir ++ "/**"),
{Dirs, Files} = lists:partition(fun filelib:is_dir/1, Paths),
ok = lists:foreach(fun file:delete/1, Files),
Sorted = lists:reverse(lists:sort(Dirs)),
ok = lists:foreach(fun file:del_dir/1, Sorted),
file:del_dir(Dir).
The example above makes a few assumptions about the current directory in relation to the target directory -- if this is an issue for your use it may be advisable to explicitly set a working directory and fully qualify the path to the target.
It is worth noting that a similar approach can be used to recursively copy directories as well.

Answer 4

Since Erlang OTP 23.0 you can use file:del_dir_r/1 function.
file:del_dir_r(File).
For the ones still using older Erlang versions, here there is, a replacement based on the source code of the new official del_dir_r fixed to work with older versions:
%% Include file.hrl to have access to #file_info{} record
-include_lib("kernel/include/file.hrl").
-spec del_dir_r(File) -> ok | {error, Reason} when
File :: file:name_all(),
Reason :: file:posix() | badarg.
del_dir_r(File) ->
case file:read_link_info(File) of
{ok, #file_info{type = directory}} ->
case file:list_dir_all(File) of
{ok, Names} ->
lists:foreach(fun(Name) ->
del_dir_r(filename:join(File, Name))
end, Names);
{error, _Reason} -> ok
end,
file:del_dir(File);
{ok, _FileInfo} -> file:delete(File);
{error, _Reason} = Error -> Error
end.