Determining default gateway with Tcl - network-programming

Question

I have a Tcl/Tk script, and I need to find the default gateway of the computer it's running on to establish a connection to the router. Is there any way (preferably cross-platform) to find out what the computer's default gateway is set to?
I imagine that for Linux (Ubuntu, specifically -- the platform I'm targeting) I could call the "route" command and parse that, but I'm not sure that would work on Windows, and I'd like to avoid making system calls if possible, on principle.

Answer 1

The way to get information about the network routing is to ask the OS. This is also an operation that isn't very cross-platform. On Windows, the simplest way to do this is to parse the output of ipconfig /all.
set output [exec {*}[auto_execok ipconfig] /all]
if {[regexp -line {Default Gateway[ .]*: (.+)} $output -> gw]} {
puts "The default gateway is $gw"
} else {
puts "No default gateway found"
}
On Linux, you need to do this:
# Note, might not be on your PATH by default
set output [exec /sbin/route -n]
if {[regexp -line {^0\.0\.0\.0\s+([0-9.]+)} $output -> gw]} {
puts "The default gateway is $gw"
} else {
puts "No default gateway found"
}
On OSX (and other BSD derivatives), you need a different incantation:
set output [exec /sbin/route -n get 0.0.0.0]
if {[regexp -line {gateway: ([0-9.]+)} $output -> gw]} {
puts "The default gateway is $gw"
} else {
puts "No default gateway found"
}
As you can see, this is frustratingly difficult! Let's wrap it up in a procedure that uses tcl_platform to decide what to do.
proc gateway {varName} {
upvar 1 $varName gw
global tcl_platform
if {$tcl_platform(platform) eq "windows"} {
set output [exec {*}[auto_execok ipconfig] /all]
set RE {Default Gateway[ .]*: (.+)}
} elseif {$tcl_platform(os) eq "Linux"} {
set output [exec /sbin/route -n]
set RE {^0\.0\.0\.0\s+([0-9.]+)}
} else {
# Assume we're OSX or BSD
set output [exec /sbin/route -n get 0.0.0.0]
set RE {gateway: ([0-9.]+)}
}
return [regexp -line $RE $output -> gw]
}
Now you'll be able to do this on all platforms:
if {[gateway gw]} {
puts "The default gateway is $gw"
} else {
puts "No default gateway found"
}
The underlying code isn't portable, but your code can be. Easy!