Comparing to two lists - xslt-2.0

Question

This is a long, long question. Apologies.
My XSLT is not too bad as you can see from my reputation. I've been struggling all day to solve a coding problem and have, in the end, come up with a solution but I don't like it.
It seems to me that I have managed to code a procedural solution in a functional language and I would welcome more elegant, cleaner solutions more in the spirit of XSLT.
I am doing a data reconciliation exercise between two computer systems holding very similar data.
The data in question is public transport Routes, each Route consisting of a list of Points e.g.
<Routes>
<Route Id="1">
<Point Id="1"/>
<Point Id="2"/>
<Point Id="3"/>
<Point Id="4"/>
<Point Id="5"/>
</Route>
</Routes>
None of the Id's are simple, incrementing integers in reality of course.
For 'Business Reasons' this Route may appear in the other system as
<Routes>
<Route Id="1">
<Point Id="1"/>
<Point Id="2"/>
</Route>
<Route Id="1A">
<Point Id="3"/>
<Point Id="4"/>
<Point Id="5"/>
</Route>
</Routes>
We can assume that the Point Id's match between the systems often enough
Now, I have code that compares Route 1 in one system and Routes that start with 1 in the other system and it produces something like:
<Routes>
<Route>
<Point Id="1" In="Y"/>
<Point Id="2" In="Y"/>
<Point Id="3" In="N"/>
<Point Id="4" In="N"/>
<Point Id="5" In="Y"/>
<Point Id="6" In="Y"/>
<Point Id="7" In="N"/>
<Point Id="8" In="N"/>
<Point Id="9" In="N"/>
</Route>
</Routes>
Where In='Y' means that point is also in System B for this Route
This sort of output is a little difficult for the business to understand. They could deal with the following easier
<Routes>
<Route>
<Route>
<Group startPoint="1" endPoint="2" In="Y"/>
<Group startPoint="3" endPoint="4" In="N"/>
<Group startPoint="5" endPoint="6 "In="Y"/>
<Group startPoint="7" endPoint="9" In="Y"/>
</Route>
</Route>
</Routes>
Obviously, I don't really show them any thing like this. I shows them Excel sheets with text description of things, But I do want to reduce points of the list that do not change status to sections with start and ends as this is much more easy to understand in business terms.
In other words they want to see that this route is the same as the first half of the other route then skips a bunch of points then matches up again.
So....
How to reduce sequences of Y and N elements to element that say we started saying Y here till here then we said N from here to here and then N for the last few. Hope this makes sense
My test data:
<Routes>
<Route>
<Point Id="1" In="Y"/>
<Point Id="2" In="Y"/>
<Point Id="3" In="N"/>
<Point Id="4" In="N"/>
<Point Id="5" In="Y"/>
<Point Id="6" In="Y"/>
<Point Id="7" In="N"/>
<Point Id="8" In="N"/>
<Point Id="9" In="N"/>
</Route>
</Routes>
My solution:
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="xs"
version="2.0">
<xsl:template match="/">
<Routes>
<xsl:apply-templates select="/Routes"/>
</Routes>
</xsl:template>
<xsl:template match="/Routes">
<Route>
<xsl:apply-templates select="Route"/>
</Route>
</xsl:template>
<xsl:template match="/Routes/Route">
<xsl:copy>
<xsl:copy-of select="#*"/>
<xsl:apply-templates select="." mode="Pointy">
<xsl:with-param name="posn" select="1" as="xs:integer"/>
<xsl:with-param name="startPosn" select="1" as="xs:integer"/>
</xsl:apply-templates>
</xsl:copy>
</xsl:template>
<xsl:template match="/Routes/Route" mode="Pointy">
<xsl:param name="posn" as="xs:integer"/>
<xsl:param name="startPosn" as="xs:integer"/>
<xsl:variable name="groupType" select="Point[position()=$startPosn]/#In"/>
<xsl:if test="$posn!=1 and $groupType != Point[$posn]/#In">
<Group>
<xsl:attribute name="startPoint" select="Point[$startPosn]/#Id"/>
<xsl:attribute name="endPoint" select="Point[$posn - 1]/#Id"/>
</Group>
</xsl:if>
<xsl:if test="$posn = count(Point)">
<Group>
<xsl:attribute name="startPoint" select="Point[$startPosn]/#Id"/>
<xsl:attribute name="endPoint" select="Point[$posn]/#Id"/>
</Group>
</xsl:if>
<xsl:if test="$groupType = Point[$posn]/#In and $posn != count(Point)">
<xsl:apply-templates select="." mode="Pointy">
<xsl:with-param name="posn" select="$posn + 1" as="xs:integer"/>
<xsl:with-param name="startPosn" select="$startPosn" as="xs:integer"/>
</xsl:apply-templates>
</xsl:if>
<xsl:if test="$groupType != Point[$posn]/#In and $posn != count(Point)">
<xsl:apply-templates select="." mode="Pointy">
<xsl:with-param name="posn" select="$posn + 1" as="xs:integer"/>
<xsl:with-param name="startPosn" select="$posn" as="xs:integer"/>
</xsl:apply-templates>
</xsl:if>
</xsl:template>
</xsl:stylesheet>

Answer 1

Given the format
<Routes>
<Route>
<Point Id="1" In="Y"/>
<Point Id="2" In="Y"/>
<Point Id="3" In="N"/>
<Point Id="4" In="N"/>
<Point Id="5" In="Y"/>
<Point Id="6" In="Y"/>
<Point Id="7" In="N"/>
<Point Id="8" In="N"/>
<Point Id="9" In="N"/>
</Route>
</Routes>
you can use group-adjacent with
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output indent="yes"/>
<xsl:template match="#* | node()">
<xsl:copy>
<xsl:apply-templates select="#* , node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="Route">
<xsl:copy>
<xsl:for-each-group select="Point" group-adjacent="#In">
<Group startPoint="{#Id}" endPoint="{current-group()[last()]/#Id}" In="{#In}"/>
</xsl:for-each-group>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
to get
<Routes>
<Route>
<Group startPoint="1" endPoint="2" In="Y"/>
<Group startPoint="3" endPoint="4" In="N"/>
<Group startPoint="5" endPoint="6" In="Y"/>
<Group startPoint="7" endPoint="9" In="N"/>
</Route>
</Routes>