RPD by group google sheets - google-sheets

Question

I want to calculate the RPD (relative percent difference) for different groups in a google sheet.
I can do it for the whole array but miss it when I add the groups. Works when I use it for percentrank though.....
For all values, works fine
=(B20-AVERAGE($B$20:$B$30))/(AVERAGE($B$20:$B$30))*100
Try A
ArrayFormula((B20-AVERAGE($B$20:$B$30))/(AVERAGE(IFERROR(B$20:B$32*IF($A$20:$A$32=$A20,1,""),""),B20)))*100
Try B
=ARRAYFORMULA(B20-average(IFERROR(($B$20:$B$32)*IF($A$20:$A$32=$A20,1,""),B20)))/AVERAGE(B20:B34)*100
sheet as screenshot shows
Any idea?
Example of table, I made all values equal besides first one to see if the calculation is right. Expected result in the last column
Group
Value
Result
PG
40
18.92
PG
33
-1.89
SF
40
18.92
PG
33
-1.89
SG
40
18.92
SG
33
-1.89
PG
33
-1.89
SF
33
-1.89
SF
33
-1.89
SF
33
-1.89
SG
33
-1.89
SG
33
-1.89
String in "Group" can be in any order so I need to find a way to handle this. In the final version I will have 25 columns I need to calculate according to "Group".

Answer 1

To calculate the difference of each value and its group's average, and divide the result by the group average, try this:
=lambda(
groupAverage,
to_percent((B2 - groupAverage) / groupAverage)
)(
average(filter(B$2:B$14, A$2:A$14 = A2))
)
To evaluate the same through the whole column with an array formula, try this:
=lambda(
groups, values,
map(
groups, values,
lambda(
group, value,
lambda(
groupAverage,
if(
len(group),
to_percent((value - groupAverage) / groupAverage),
iferror(1/0)
)
)(
iferror(average(filter(values, groups = group)))
)
)
)
)(
A2:A, B2:B
)
To get the previous value in the same group on a row-by-row basis, try this:
=single( iferror( sort( filter( { B$1:B1, row(B$1:B1) }, A$1:A1 = A2 ), 2, false ), B2 ) )
To get the relative change to previous value in the same group, try this:
=to_percent( iferror((B2 - C2) / B2) )
See the sample spreadsheet.