Google sheets calculation for a period of time, please assist - google-sheets

Question

Use sumifs to calculate "the profit" on "monday" between 0:00 and 1:00.
C:C profit, A:A date and B:B time. The function below does not return anything
=SUMIFS(C1:C1000,A1:A1000,"Monday",B1:B1000,">=00:00",B1:B1000,"<01:00")
Can someone assist me by using google sheets calculation the output being profits made between different times and for days of the week? Below is the sample data
Below is the blank sheet maker
https://docs.google.com/spreadsheets/d/1c6CcaUyry48kogVNmyogFytjGiRWwXIKO7_ikwLik4k/edit

Answer 1

One way to do that is to use filter(), like this:
=sum(
filter(
A2:A,
text(B2:B, "ddd") = "Mon",
value("0:00 am") <= C2:C, C2:C < value("1:00 pm")
)
)
The formula above assumes that profits are in column A2:A, dates in column B2:B and times in column C2:C as per the table shown in the question. In the event those values are in a different order in the columns suggested by the formula in the question, use this instead:
=sum(
filter(
C1:C,
text(A1:A, "ddd") = "Mon",
value("0:00 am") < B1:B, B1:B < value("1:00 pm")
)
)
You can also use named ranges, like this:
=sum(
filter(
Profit,
text(Date, "ddd") = "Mon",
value("0:00 am") <= Time, Time < value("1:00 pm")
)
)
The three named ranges must be exactly of the same height.
If the spreadsheet locale is such that the name of Monday is something else, replace Mon with something else. You should also use 24-hour time format such as 13:00 instead of 01:00 pm when the locale so requires.
The layout of data in your sample spreadsheet differs considerably from what you present in the question. Further, the values in column P are not dates but text strings that just look like dates.
With those handicaps, you can best get an hourly report pivoted by day of week using a couple of helper columns and query(), like this:
=arrayformula(
lambda(
daySerial,
if(
len(daySerial),
weekday(daySerial, 2) & text(daySerial, " dddd"),
iferror(1/0)
)
)(
iferror(value(substitute(P2:P, ".", "/")))
)
)
=arrayformula(
if(
len(Q2:Q),
value(regexextract(to_text(Q2:Q), "\d+")),
iferror(1/0)
)
)
=query(
N1:U,
"select U, sum(N)
where U is not null
group by U
pivot T",
1
)
See your sample spreadsheet.