How to use kbmMWConfiguration.Configuration as Memory only - delphi

Question

I know, that I can use the Configuration object to create files:
// Config.PrepareYAMLStorage;
// Config.PrepareBSONStorage;
// Config.PrepareJSONStorage;
Config.PrepareXMLStorage;
These files are created automatically when the object is destroyed. I want to use the class as memory only, so I can persist the content of Config.Storage on a database.
Is there a variant of Storage, that has something like a Storage.AsString or how can I create a replacement of the exiting Storage, that can do this?

Answer 1

There are a couple of ways.
The "intended" way is to create your own storage method for the configuration object.
If you want to have the data as JSON, you can inherit from kbmMW 's TkbmMWJSONConfigurationStorage and add a couple of methods that provides a string with the JSON data in it.
Eg.
TMyStorage = class(TkbmMWJSONConfigurationStorage)
protected
function GetConfigurationAsString:string;
procedure SetConfigurationAsString(const AString:string);
public
property ConfigurationAsString:string read GetConfigurationAsString write SetConfigurationAsString;
end;
...
function TMyStorage.GetConfigurationAsString:string;
var
str:TkbmMWJSONStreamer;
begin
str:=TkbmMWJSONStreamer.Create;
try
Result:=str.SaveToUTF16String(&ON);
finally
str.Free;
end;
end;
procedure TMyStorage.SetConfigurationAsString(const AString:string);
var
str:TkbmMWJSONStreamer;
co:TkbmMWONCustomObject;
begin
str:=TkbmMWJSONStreamer.Create;
try
co:=str.LoadFromUTF16String(AString);
if co.IsObject then
begin
&ON.Free;
&ON:=TkbmMWONObject(co);
end
else
co.Free;
finally
str.Free;
end;
end;
Then
var
myStorageInstance:TMyStorage;
begin
myStorageInstance:= TMyStorage.Create('somepathtojsonstorage',false);
Configuration.Storage:=myStorageInstance;
end;
Notice that this will still save and load the configuration to and from a file. If you want to prevent that, override the Save and Load methods and make them do nothing.
But it does provide you with a way to access the JSON storage as a string.
It however also prevents you from switching the storage out at will, since a complete registry based storage usually will not easily be able to be set from a string or read to a string.
/Kim/C4D