NSIS read value from listbox and write it to registry - listbox

Question

I’ve been struggling for a while with NSIS, I need a listbox filled with 300 values like
Value Label
Then take selected value and write it to registry. So far I was able to create the listbox but hadn’t luck getting selected value. Any idea or example. Thanks

Answer 1

!include nsDialogs.nsh
Var ListboxValue
Function .onInit
StrCpy $ListboxValue "xyz" ; Default value used in silent installers
FunctionEnd
Page Custom MyPageCreate MyPageLeave
Page InstFiles
!define LISTITEMSEP ": "
Function MyPageCreate
nsDialogs::Create 1018
Pop $0
${NSD_CreateListBox} 0 0 100% 50% ""
Pop $1
${NSD_LB_AppendString} $1 "Foo${LISTITEMSEP}Bar"
${NSD_LB_AppendString} $1 "Hello${LISTITEMSEP}World"
${NSD_LB_SetSelectionIndex} $1 0 ; Select the first item by default
nsDialogs::Show
FunctionEnd
Function MyPageLeave
${NSD_LB_GetSelection} $1 $2
; Extract the part after the separator
StrLen $3 "${LISTITEMSEP}"
StrCpy $4 0
loop:
StrCpy $5 $2 $3 $4
${If} $5 != "${LISTITEMSEP}"
IntOp $4 $4 + 1
StrCmp $5 "" 0 loop
${EndIf}
IntOp $4 $4 + $3
StrCpy $ListboxValue $2 "" $4
${If} $ListboxValue == ""
MessageBox MB_ICONSTOP "Please select something!"
Abort
${EndIf}
FunctionEnd
Section
MessageBox MB_OK "Write $ListboxValue to the registry here"
SectionEnd
You can also use ${NSD_LB_SetItemData} and ${NSD_LB_GetItemData} if you need to assign a numeric value to each item.