Use IFS() to return a range - google-sheets

Question

I'm writing a Google Sheets named function, GETTABLEOFCELL(), that takes in a cell reference, and returns the Named Range that cell exists in.
Since I could not find a native function to determine if a cell is within the specified range, I've defined a helper function called ISCELLINRANGE(range, cell). I've confirmed that this helper function works for cells and ranges within the same sheet--good enough for my case.
ISCELLINRANGE(range, cell)
=AND(
ROW(cell) >= ROW(range),
ROW(cell) < ROW(range) + ROWS(range),
COLUMN(cell) >= COLUMN(range),
COLUMN(cell) < COLUMN(range) + COLUMNS(range)
)
GETTABLEOFCELL(tableCell)
=ARRAYFORMULA(
IFS(
ISCELLINRANGE(DeathWaveUW, tableCell), {DeathWaveUW},
ISCELLINRANGE(BlackHoleUW, tableCell), {BlackHoleUW},
// ...
)
)
///
=ISCELLINRANGE(DeathWaveUW, D6) // => TRUE
=COLUMN(GETTABLEOFCELL(D6)) // => #VALUE!
=ARRAYFORMULA(
IFS(
ISCELLINRANGE(DeathWaveUW, D6), DeathWaveUW
)
) // => #N/A
As seen above, to debug GETTABLEOFCELL(), I simply copied a snippet of the formula into a cell with hard-coded values. It returns #N/A saying there is no match in the IFS() list, which I am guessing (read: hoping) is the root issue in GETTABLEOFCELL(). I've used both DeathWaveUW and {DeathWaveUW} syntaxes for the second argument of IFS; both return #N/A.
Any idea what I am doing wrong?

Answer 1

Issue:
IFS returns
#N/A, when none of the conditions is satisfied
#VALUE, when there are mismatched ranges
Solution:
For
#N/A, Add a default value to IFS
#VALUE, Fix the range size
Sample:
#N/A
Add a default value:
GETTABLEOFCELL(tableCell)
=ARRAYFORMULA(
IFS(
ISCELLINRANGE(DeathWaveUW, tableCell), {DeathWaveUW},
ISCELLINRANGE(BlackHoleUW, tableCell), {BlackHoleUW},
TRUE, "No range found"
)
)
This assumes All *UWs are of single range. If not, TRUE and "No range found" should be modified to a array(MAKEARRAY is a option).
#VALUE
If DeathWaveUW and BlackHoleUW and all other UWs were two dimensional and of the same size, you can change the aggregating function AND to a non-aggregating function like * to maintain the array size:
ISCELLINRANGE(range, cell)
=
(ROW(cell) >= ROW(range))*
(ROW(cell) < ROW(range) + ROWS(range))*
(COLUMN(cell) >= COLUMN(range))*
(COLUMN(cell) < COLUMN(range) + COLUMNS(range))
Alternatively, reduce the array size of named range to 1 by passing it as a string and use INDIRECT
GETTABLEOFCELL(tableCell)
=ARRAYFORMULA(
INDIRECT(
IFS(
ISCELLINRANGE(DeathWaveUW, tableCell), "DeathWaveUW",
ISCELLINRANGE(BlackHoleUW, tableCell), "BlackHoleUW",
TRUE, "No range found"
)
)
)
Related:
ArrayFormula and "AND" Formula in Google Sheets
Mismatch Range error on using IFs in sheets