Display Top 5 Entires from Matching Keys in Sheets - google-sheets

Question

This is a little more complex than the title makes it out to be and I'm having difficulty figuring out a way to go about it.
I have a set of tables which record the 20 highest values and their corresponding keys from a larger list of keys and values.
Right now my formulas are: For values
=LARGE(Values!$K$3:Values!$K$999,ROW(J4)-ROW(J$3)) for Values and
=INDEX(Values!$L$3:Values!$L$999,MATCH(J4,Values!$K$3:Values!$K$5000,0)) to select matching keys
This approach works for selecting all N desired values, but will select whatever the top values are, without regard for keys, allowing a column of entirely A values for example.
What I want is:
Display top N (20) values with the caveat that:
Only the top M (5) values for each key are displayed.
For example, with N of 5 and M of 2, this is what I would want.
Given data:
Key
Value
A
100
B
200
C
300
A
400
A
600
B
140
C
100
A
350
I would want the resulting table to look like this:
Key
Value
A
600
A
400
C
300
B
200
B
140
In this system, keys are unpredictable, and there can be fewer than M entries per key, or many more than M entries per key. Values might not be unique, but I haven't found a good way to address this either, and it happens very infrequently.

Answer 1

max(B) for each unique A:
=SORTN(SORT(A:B, 2, ), 9^9, 2, 1, 1)
max(B) for each unique A but only the highest N(2) returned:
=SORTN(SORTN(SORT(A:B, 2, ), 9^9, 2, 1, 1), N(2),, 2, )
top N(2) values of B for every A and final output limited to top M(5):
=QUERY(FILTER(SORT(A:B, 2, ),
COUNTIFS(SORT(A:A, B:B, 0), SORT(A:A, B:B, 0), ROW(A:A), "<="&ROW(A:A))
<=N(2)), "limit 5", )