Check if cell contain string - google-sheets

I would like to check if a specific URL contains any string from date base.
Here You got a screenshot with an explanation.
Link to the example sheet:
https://docs.google.com/spreadsheets/d/16dvAx_MCycICUqsNXjHieeIPE80wHH5brq8qcDVQjJ8/edit?usp=sharing


use:
=ARRAYFORMULA(REGEXMATCH(B2:B23, TEXTJOIN("|", 1, D2:D23))*1)

Related

Textjoin or Concatenate for this case?

hope you have a good day/evening.
Due to I always seems to use importrange function to import multiple sheets. I want to have a quicker way to replace the date (highlighted in red as per the screenshot) with the date referenced in Col A. This is my Google Sheet under the tab name "TextJoin" Google Sheets Link

try:
=INDEX({""; "={"&TEXTJOIN("; ", 1,
"IMPORTRANGE(""13DWtP4L7swqBgK6BGLeA-o_FfyD-D8-Ru30cOPf0I10"", """&
FILTER(TO_TEXT(A2:A)&"!A2:C"")", A2:A<>""))&"}"})
but you may need to wrap it into query and remove empty rows perhaps like:
=INDEX({""; "=QUERY({"&TEXTJOIN("; ", 1,
"IMPORTRANGE(""13DWtP4L7swqBgK6BGLeA-o_FfyD-D8-Ru30cOPf0I10"", """&
FILTER(TO_TEXT(A2:A)&"!A2:C"")", A2:A<>""))&"}, ""where Col1 is not null"", )"})

Try
=importrange("_____","'" & text(A2,"M/d/yy") &"'!A2:C")

Comparing string with

In Google Sheets, I'm trying to indicate whether each cell in a specific column (the "Target Column") contains any of the words listed in a group of cells (the "Word Warehouse"), organized into different "Categories". If the word appears in the Word Warehouse, I would like the cell to spit out the category that it's listed under, e..
See attached sheet here: https://docs.google.com/spreadsheets/d/10jiicpOpplaURrF0UtTi9HM2TFP04-tinynpnFef2mE/edit#gid=0
Thanks in advance!

Try:
=INDEX($2:$2,1,MAX((ISNUMBER(SEARCH(IF(LEN($D$3:$F$7),$D$3:$F$7),A3))*COLUMN($D$3:$F$7))))

Alternatively, you can also try
=ArrayFormula(iferror(VLOOKUP(regexextract(proper(A2:A), textjoin("|", 1, D2:F)), split(flatten(D2:F&"_"&D1:F1),"_"), 2, 0)))
This formula allows for an array output, so dragging down is not necessary.

Copy Row To Another Sheet Based On Cell Value In Google Sheet

I'm Trying it:
=FILTER('Orginal'!A:D, 'Orginal'!D:D="Complete")
Screens:
And i have Error. "formula analysis error"
What im doing wrong?

You are having a syntax error here:
Please use the following formula:
=FILTER('Orginal'!A2:D, 'Orginal'!D2:D="Complete")
update after finding solution
It turns out the solution had to do with the spreadsheet location.
The location of the spreadsheet can determine if the formulas have either a comma or a semicolon, as well as the format of the dates. To change your location of the spreadsheet, you can do it in:
file => spreadsheet settings => locale and change the locale there.

Yeah bad screen.. but i found it... it was problem with this:
It shoud be :
=FILTER(Orginal!A:D;Orginal!D:D="Complete")
i changed "," to ";"

Google Sheets: "Bob Smith" --> "bsmith" formula?

I'm trying to pull data from another Google Sheet to feed another Google Sheet. I need to pull from a full name field, which will have something like, "Bob Smith" and then I need to have it rewrite into the new Google Sheet as "bsmith".
Basically, "Get first letter of the first string, then concatenate the entire second string, and then make all lowercase."
So far I've gotten =LEFT(A28,1) working to grab the first letter of a string, but then not sure how to grab the second word and then concatenate.

To get the 2nd word you need to FIND() the first space then read from that position + 1 to the end of the string using MID(). & is used for concatenation.
=lower(left(A28,1) & mid(A28, find(" ", A28) + 1, len(A28)))

Try this for a Google sheet specific solution:
=LOWER(REGEXREPLACE(A2,"^(\w).*?(\w+$)","$1$2"))
It uses REGEX, a much more sophisticated engine and easily adaptable to variations than LEFT and/or MID.

Shorter:
=lower(left(A28)&index(split(A28," "),2))
(Assumes only ever two words.)

How do I use a Cell value inside of a string?

I have the following in my Google Sheet to pull number of views from a YouTube page:
=IMPORTXML("https://www.youtube.com/watch?v=i1D8XIIvYS0","//div[#class='watch-view-count']")
I'd like to split out the YouTube ID into a different column and do the following where B2 is the cell with the value 'i1D8XIIvYS0'
=IMPORTXML("https://www.youtube.com/watch?v=B2","//div[#class='watch-view-count']")
How do I escape 'B2' so that the value is used here?

=IMPORTXML("https://www.youtube.com/watch?v="&B2,"//div[#class='watch-view-count']")
If your referencing b2 you just need to remove the quote from after it to in front of it and use the & to join the value with the string

Try:
=IMPORTXML("https://www.youtube.com/watch?v="& B2 &"","//div[#class='watch-view-count']")

Resources