I have formula to auto fill data like column A. It is no need to hand dragging or auto filling by suggestion.
Here column A is perfectly done. Cell A1 formula as below:
={ "VendorNo"; unique(General!A2:A) }
Cell B1 formula is correct as below:
LOOKUP(VendorStatus!A2,sort(General!A2:A),sort(General!C2:C,General!A2:A,TRUE))
Once cell A1 is done, all A column is real auto filled. All I want is to do is the same effect like cell A1. How can I rewrite B1 formula to auto filled the rest B column value?
P.S.: I am sorry I couldn't post image above directly because I don't have enough reputation.
Try in B1 (assuming your formula gives you the right answer)
={"EventStartDate";arrayformula(if(A2:A="",,LOOKUP(A2:A,sort(General!A:A),sort(General!C:C,General!A:A,TRUE))))}
try in row 1:
={"event start date"; INDEX(IFNA(VLOOKUP(A2:A, General!A2:C, 3, 0)))}
or:
={"event start date"; INDEX(IFNA(VLOOKUP(A2:A,
SORT(General!A2:C, ROW(General!A2:C), 0), 3, 0)))}
Related
How would I do it so if I had a list of numbers, how could I get every number below A1 to be minuses from A1 and put next to that cell?
Paste this in B2 or see the Example Sheet
=ArrayFormula(IF(A2:A="",,A2:A-$A$1))
What about this simple formula in A2 cell?
=INDEX(A1+B2:B6)
how can I subtract cells A2 from A1 without directly using cell addresses? I would like to write A2 as a cell -1 column away and A1 as a cell -1 column away and -1 row away.
image
Thanks in advance <3
You can make use of the offset function on sheets.
An example formula based on your example would be: =(OFFSET(B2,0,-1)-OFFSET(B2,-1,-1))
You can use the INDIRECT function along with ADDRESS, ROW and COLUMN
=INDIRECT(ADDRESS(ROW(),COLUMN()-1))-INDIRECT(ADDRESS(ROW()-1,COLUMN()-1))
You can also use Indirect with RC notation as below:
=indirect("RC[-1]",false)-indirect("R[-1]C[-1]",false)
I want to sum-up all of previous value.
for example like image.
If current cell is C2, then show A2.
If current cell is C3, then show SUM(A2:A3).
If current cell is C4, then show SUM(A2:A4)
So in cell C2 , your start cell, put:
=Sum(A$2:A2)
Now copy paste it to all the cells in the column you want - C, or simply Drag Down the formula.
Probably more alternatives, but try:
Formula in B2:
=ArrayFormula(IF(LEN(A2:A),(SUMIF(ROW(A2:A),"<="&ROW(A2:A),A2:A)),))
try in C2:
=ARRAYFORMULA(IF(A2:A="";;MMULT(TRANSPOSE((ROW(A2:A500)<=
TRANSPOSE(ROW(A2:A500)))*A1:A500); SIGN(A2:A500))))
I would like to plot sparklines (barchart with the value to show in B-row and the max-value in die C-row: see linked file) in every cell from A2 to A5 using ony one arrayformula (=ARRAYFORMULA( ...) in A2 which can plot spakrlines in every cell from A2 to A5.
Link to file: sparkline arrayformula
Thx for any help,
Gerd
SPARKLINE does not work with arrayformula. I think the best you can do is put this in A2 and drag it down past A5. It will pick up new data.
=iferror(SPARKLINE(B2,{"charttype","bar";"max",C2}),"")
Hmm
Make a blank column A:A.
=ARRAYFORMULA(IF(ISBLANK($A$1:$A),"", SPARKLINE({0,1},{"color","#ddd"})))
How can I get the result as in example with ARRAYFORMULA up to last filled cell A?
I can do it with formula in cell C1 =MAX(B$1:B1) but in that case have to copy the formula in each cell in turn.
In C2 try:
=ArrayFormula(if(row(A2:A) <= max(if(not(isblank(A2:A)), row(A2:A))),vlookup(row(A2:A),filter({row(A2:A),B2:B},len(B2:B)),2),))
See this spreadsheet for an example.