Query ImportRange on Google Sheets breaks with extra parameter - google-sheets

Question

So I'm wondering why when I add an extra two parameters (one on each function) that I get an Array literal error. Below is the function that runs perfectly fine.
={QUERY(IMPORTRANGE("url", "INVENTORY!$A:$Z"),
"SELECT Col1,Col2,Col3,Col4,Col5,Col15,Col17,Col18,Col7,Col11,Col12,Col13,Col14,Col21 WHERE Col15 IS NOT NULL
AND Col15 < "&F1&"
AND Col19 <> 'Printed'
AND Col20 = 'Restock'
ORDER BY Col15 ASC", 1);
QUERY(IMPORTRANGE("url", "PREINVENTORY!$A:$Z"),
"SELECT Col1,Col2,Col3,Col4,Col5,Col8,Col9,Col10,Col11,Col12,Col13,Col14,Col15,Col19 WHERE Col19 <> 'FBA' AND Col17 = 1 AND Col7 IS NULL",0)}
When I add an extra parameters the sheet breaks and I get the array literal error suggesting I has mismatched columns sizes.
={QUERY(IMPORTRANGE("url", "INVENTORY!$A:$Z"),
"SELECT Col1,Col2,Col3,Col4,Col5,Col15,Col17,Col18,Col7,Col11,Col12,Col13,Col14,Col21 WHERE Col15 IS NOT NULL
AND Col15 < "&F1&"
AND Col19 <> 'Printed'
AND Col20 = 'Restock'
AND Col22 = 1
ORDER BY Col15 ASC", 1);
QUERY(IMPORTRANGE("url", "PREINVENTORY!$A:$Z"),
"SELECT Col1,Col2,Col3,Col4,Col5,Col8,Col9,Col10,Col11,Col12,Col13,Col14,Col15,Col19 WHERE Col19 <> 'FBA' AND Col17 = 1 AND Col7 IS NULL AND Col22 = 1",0)}

Answer 1

Most probably one of your qyeries results in #N/A. Try accounting for that with IFNA like this:
={
IFNA(
QUERY(
IMPORTRANGE("url", "INVENTORY!$A:$Z"),
"SELECT Col1, Col2, Col3, Col4,
Col5, Col15, Col17, Col18,
Col7, Col11, Col12, Col13,
Col14, Col21
WHERE Col15 IS NOT NULL
AND Col15 < " & F1 & "
AND Col19 <> 'Printed'
AND Col20 = 'Restock'
AND Col22 = 1
ORDER BY Col15",
1
),
{"Query returned nothing", SPLIT(REPT(",", 12), ",",,)}
);
IFNA(
QUERY(
IMPORTRANGE("url", "PREINVENTORY!$A:$Z"),
"SELECT Col1, Col2, Col3, Col4,
Col5, Col8, Col9, Col10,
Col11, Col12, Col13, Col14,
Col15, Col19
WHERE Col19 <> 'FBA'
AND Col17 = 1
AND Col7 IS NULL
AND Col22 = 1",
0
),
{"Query returned nothing", SPLIT(REPT(",", 12), ",",,)}
)
}