Simplifying pattern match - f#

Question

I have these types
type IntervalWithBreak = { Start: DateTime; End: DateTime }
type IntervalWithoutBreak = { Start: DateTime; End: DateTime; Break: TimeSpan }
type WorkTime =
| Workshop of IntervalWithBreak
| Mounting of IntervalWithBreak
| Ill of IntervalWithoutBreak
type WorktimeDefinition = {Weekday: DayOfWeek}
Now I want to create a function which allows me to find elements matching a condition.
Code completion for workTime in the matches function however doesn't provide the Start or End fields until I use this pattern match.
let matches (worktime:WorkTime) (worktimeDefinition:WorktimeDefinition) =
match worktime with
| Workshop w -> w.Start.DayOfWeek = worktimeDefinition.Weekday
| Mounting m -> m.Start.DayOfWeek = worktimeDefinition.Weekday
| Ill i -> i.Start.DayOfWeek = worktimeDefinition.Weekday
List.find (matches worktime) definitions
Can I have a more generic match so I don't have to check against all union cases but instead match against IntervalWithoutBreak and IntervalWithBreak?
My type definition is based on this suggestion.

Answer 1

As the argument of the Workshop case and the Mounting case is of the same type, the first thing you can do is to join them into an or-pattern:
let matches (worktime:WorkTime) (worktimeDefinition:WorktimeDefinition) =
match worktime with
| Workshop m
| Mounting m -> m.Start.DayOfWeek = worktimeDefinition.Weekday
| Ill i -> i.Start.DayOfWeek = worktimeDefinition.Weekday
This will not work for the Ill case, which contains an argument of a different type. But since they are all records, you can deconstruct the record in the pattern matching too:
let matches (worktime:WorkTime) (worktimeDefinition:WorktimeDefinition) =
match worktime with
| Workshop { Start = start }
| Mounting { Start = start }
| Ill { Start = start } -> start.DayOfWeek = worktimeDefinition.Weekday
As you now have just one case, you could actually write this using let, but I probably would not do this. I think match is more readable. But just for the record:
let matches (worktime:WorkTime) (worktimeDefinition:WorktimeDefinition) =
let (Workshop { Start = s } | Mounting { Start = s } | Ill { Start = s }) = worktime
s.DayOfWeek = worktimeDefinition.Weekday