How to detect right-click on a TMenuItem with WM_MENURBUTTONUP? - delphi

Question

In a 32-bit Delphi 11 VCL Application on Windows 10, I use a TApplicationEvents component to catch Windows Messages. Unfortunately, TApplicationEvents seems to not react to the WM_MENURBUTTONUP message when I RIGHT-CLICK on a TPopupMenu MenuItem:
procedure TForm1.ApplicationEvents1Message(var Msg: tagMSG; var Handled: Boolean);
begin
case Msg.message of
Winapi.Messages.WM_MENURBUTTONUP: CodeSite.Send('TForm1.ApplicationEvents1Message: WM_MENURBUTTONUP');
end;
end;
The Microsoft documentation says:
WM_MENURBUTTONUP message
Sent when the user releases the right mouse button while the cursor is on a menu item.
As an alternative, WM_COMMAND is sent with BOTH Left- and Right-Clicks. However, for a specific purpose, I need to react only when RIGHT-Clicking a menu item.

Answer 1

The quoted part of the documentation explains why you aren't seeing this message:
Sent when the user [...]
The TApplicationEvents.OnMessage event is only able to detect posted messages, not sent messages.
TMainMenu
So if you want to detect this message, you can add
protected
procedure WndProc(var Message: TMessage); override;
to your form class, implemented as follows:
procedure TForm1.WndProc(var Message: TMessage);
begin
if Message.Msg = WM_MENURBUTTONUP then
ShowMessage('rbu')
else
inherited
end;
Try, for instance:
procedure TForm1.WndProc(var Message: TMessage);
begin
if Message.Msg = WM_MENURBUTTONUP then
begin
var MI := Menu.FindItem(Message.LParam, fkHandle);
if Assigned(MI) and InRange(Message.WParam, 0, MI.Count - 1) then
ShowMessageFmt('Menu item "%s" right clicked.', [MI.Items[Message.WParam].Caption]);
end
else
inherited
end;
TPopupMenu
For a TPopupMenu, you need to write your own TPopupList descendant:
type
TPopupListEx = class(TPopupList)
protected
procedure WndProc(var Message: TMessage); override;
end;
{ TPopupListEx }
procedure TPopupListEx.WndProc(var Message: TMessage);
begin
if Message.Msg = WM_MENURBUTTONUP then
ShowMessage('rbu')
else
inherited
end;
initialization
FreeAndNil(PopupList);
PopupList := TPopupListEx.Create;
And make sure to set the TPopupMenu's TrackButton to tbLeftButton.
If you have several popup menus, you might try something like this (not fully tested):
procedure TPopupListEx.WndProc(var Message: TMessage);
begin
if Message.Msg = WM_MENURBUTTONUP then
begin
for var X in PopupList do
if TObject(X) is TPopupMenu then
begin
OutputDebugString(PChar(TPopupMenu(X).Name));
var MI: TMenuItem;
if TPopupMenu(X).Handle = HMENU(Message.LParam) then
MI := TPopupMenu(X).Items
else
MI := TPopupMenu(X).FindItem(HMENU(Message.LParam), fkHandle);
if Assigned(MI) and InRange(Message.WParam, 0, MI.Count - 1) then
begin
ShowMessageFmt('Menu item "%s" right clicked.', [MI.Items[Message.WParam].Caption]);
Break;
end;
end;
end
else
inherited
end;