How to save table output from Stata's pstest - save

Question

How to save table output from Stata's pstest
I want to save the output from Stata's pstest command with the option both after running psmatch2. I use pstest in a loop that produces hundreds of tables so copying and pasting individual tables from the screen isn't practical. I've seen this question asked elsewhere, but I haven't seen a workable solution. putdocx does not work to the best of my knowledge.
My question
My solution below works if the options logit, k-nearest neighbour matching (where k = 5), Abadie and Imbens standard errors, average treatment effects and common support are chosen for psmatch2 (logit n(5) ai(5) ate common) and both is the option chosen for the subsequent pstest command, like so pstest, both atu. Is there a better, more flexible solution that doesn't require re-writing my code if any of these options change?
To be clear, I'm not looking for anyone to edit my code. My solution works but is long and difficult to revise if different options are specified. A better answer would be simpler, much shorter, and flexible enough to show results when different options are chosen. A solution using putdocx would be ideal.
A suggestion
If it is possible, I would suggest that Stata consider requiring authors of packages to make any output to the screen retrievable in some way, perhaps using return list or ereturn list. Only the last table produced using pstest can be retrieved this way. I believe, pstest saves the output in the first of two tables in temporary memory, which is lost when the second table is created. Output from the second is available to users via return list. If I am mistaken about this, please let me know.
My solution, so far
This code works, but it is more of a workaround than a solution. In the absence of something better, I hope it will help anyone in a bind similar to the one in which I found myself.
* Most of this code is from the pstest.ado by Leuven and Sianesi (2003)
clear all
set more off
* Define the program to generate output from the Stata command pstest
cap program drop pstest_tab
program define pstest_tables
args exog atu
/* _weight is conditional on ATU option */
qui replace _weight = _support if _treated==0
local i = 0
local cont_cnt = 0 /* counting continuous vars */
local cont_varbef = 0 /* counting continuous vars w/ excessive var ratio*/
local cont_varaft = 0
qui g _bias0 = .
qui g _biasm = .
qui g sumbias = .
qui g sumbias0 = .
scalar wd_num = `:word count `exog''
mat A = J(wd_num,13,.)
mat R = J(1,16,.)
qui count if _treated==1 & esample==1
scalar Flowu = invF(r(N)-1, r(N)-1, 0.025)
scalar Fhighu = invF(r(N)-1, r(N)-1, 0.975)
qui count if _treated==1 & _support==1 & esample==1
scalar Flowm = invF(r(N)-1, r(N)-1, 0.025)
scalar Fhighm = invF(r(N)-1, r(N)-1, 0.975)
foreach v of local exog {
local ++i
/* Calculate stats for varlist */
qui sum `v' if _treated==1
scalar m1u = r(mean)
scalar v1u = r(Var)
mat A[`i',1] = r(mean)
qui sum `v' if _treated==0
scalar m0u = r(mean)
scalar v0u = r(Var)
mat A[`i',2] = r(mean)
qui sum `v' [iw=_weight] if _treated==1 & _support==1 & esample==1
scalar m1m = r(mean)
scalar v1m = r(Var)
mat A[`i',3] = r(mean)
qui sum `v' if _treated==0 & _support==1 & esample==1
scalar m0m = r(mean)
scalar v0m = r(Var)
mat A[`i',4] = r(mean)
/* Get Var ratio */
scalar v_ratiobef = v1u/v0u
scalar v_ratioaft = v1m/v0m
mat A[`i',12] = v1u/v0u
mat A[`i',13] = v1m/v0m
/* Get Var ratio */
capture assert `v'==0 | `v'==1 | `v'==., fast
if (_rc) {
local cont_cnt = `cont_cnt' +1
scalar v_ratiobef = v1u/v0u
if v_ratiobef>Fhighu | v_ratiobef<Flowu {
local cont_varbef = `cont_varbef' +1
}
scalar v_ratioaft = v1m/v0m
if v_ratioaft>Fhighm | v_ratioaft<Flowm {
local cont_varaft = `cont_varaft' +1
}
}
/* Standardised bias before matching */
scalar bias = 100*(m1u - m0u)/sqrt((v1u + v0u)/2)
mat A[`i',5] = bias
qui replace _bias0 = bias in `i'
qui replace sumbias0 = abs(bias) in `i'
/* Standardised bias after matching */
scalar biasm = 100*(m1m - m0m)/sqrt((v1u + v0u)/2)
mat A[`i',6] = biasm
qui replace _biasm = biasm in `i'
qui replace sumbias = abs(biasm) in `i'
/* Reduction in absolute bias */
mat A[`i',7] = -100*(abs(biasm) - abs(bias))/abs(bias)
/* t-tests before matching */
qui regress `v' _treated
mat A[`i',8] = _b[_treated]/_se[_treated]
mat A[`i',9] = 2*ttail(e(df_r),abs(_b[_treated]/_se[_treated]))
/* t-tests after matching */
qui regress `v' _treated [iw=_weight] if _support==1 & esample==1
mat A[`i',10] = _b[_treated]/_se[_treated] //taft
mat A[`i',11] = 2*ttail(e(df_r),abs(_b[_treated]/_se[_treated])) //paft
scalar vrb = 100*`cont_varbef'/`cont_cnt'
scalar vra = 100*`cont_varaft'/`cont_cnt'
}
/* Get overall stats for the second table */
qui probit _treated `exog' if esample==1
qui predict double index0 if e(sample), xb
mat R[1,1] = e(r2_p) // r2bef
mat R[1,3] = e(chi2) // chibef new
mat R[1,5] = chi2tail(e(df_m), e(chi2)) // probbef
qui probit _treated `exog' [iw=_weight] if _support==1 & esample==1
qui predict double indexm if e(sample), xb
mat R[1,2] = e(r2_p) // r2aft
mat R[1,4] = e(chi2) // chibef
mat R[1,6] = chi2tail(e(df_m), e(chi2)) //probaft
qui replace _bias0 = bias in `i'
qui replace sumbias0 = abs(bias) in `i'
qui replace _biasm = biasm in `i'
qui replace sumbias = abs(biasm) in `i'
qui sum sumbias0, detail
mat R[1,7] = r(mean) // meanbiasbef
mat R[1,9] = r(p50) // medbiasbef
qui sum sumbias, detail
mat R[1,8] = r(mean) // meanbiasaft
mat R[1,10] = r(p50) // medbiasaft
qui sum index0 if _treated==1 & esample==1
scalar mi1 = r(mean)
scalar vi1 = r(Var)
qui sum index0 if _treated==0 & esample==1
scalar mi0 = r(mean)
scalar vi0 = r(Var)
mat R[1,11] = 100*(mi1 - mi0)/sqrt((vi1 + vi0)/2) // ibiasbef
mat R[1,13] = vi1/vi0 // iratiobef
qui sum indexm [iw=_weight] if _treated==1 & _support==1 & esample==1
scalar mi1 = r(mean)
scalar vi1 = r(Var)
qui sum indexm [iw=_weight] if _treated==0 & _support==1 & esample==1
scalar mi0 = r(mean)
scalar vi0 = r(Var)
mat R[1,12] = 100*(mi1 - mi0)/sqrt((vi1 + vi0)/2) // ibiasaft
mat R[1,14] = vi1/vi0 // iratioaft
mat R[1,15] = 100*`cont_varbef'/`cont_cnt'
mat R[1,16] = 100*`cont_varaft'/`cont_cnt'
end
* Get example dataset
webuse cattaneo2, clear
* Keep only the used variables
keep mbsmoke foreign alcohol mage medu fage fedu bweight
* Run psmatch2
qui psmatch2 mbsmoke foreign alcohol mage medu fage fedu, out(bweight) logit n(5) ai(5) ate common
qui gen esample=e(sample)
mat P=J(1,13,.)
local xvars foreign alcohol mage medu fage fedu
pstest_tables "`xvars'" "`r(atu)'"
* Run the pstest_tables function
qui psmatch2 mbsmoke foreign alcohol mage medu fage fedu, out(bweight) logit n(5) ai(5) ate common
pstest, both atu
mat li A
mat li R
matrix colnames R = "R2(U)" "R2(M)" "LRchi2(U)" "p>chi2(U)" "MeanBias(U)" "MedBias(U)" "B(U)" ///
"R(U)" "%Var(U)" "LRchi2(M)" "p>chi2(M)" "MeanBias(M)" "MedBias(M)" "B(M)" "R(M)" "%Var(M)"
* Reshape the matrix to resemble the tables from pstest
mat B = A[1..6,1..4]
mata : M = colshape(st_matrix("B"),2)
mata : st_matrix("B",M)
mat C = A[1..6,5..6]
mata: M = colshape(st_matrix("C"),1)
mata : st_matrix("C",M)
mat D = J(12,1,.)
mat D[2,1] = A[1,7]
mat D[4,1] = A[2,7]
mat D[6,1] = A[3,7]
mat D[8,1] = A[4,7]
mat D[10,1] = A[5,7]
mat D[12,1] = A[6,7]
mat E = A[1..6,8..11]
mata: M = colshape(st_matrix("E"),2)
mata : st_matrix("E",M)
mat F = A[1..6,12..13]
mata: M = colshape(st_matrix("F"),1)
mata : st_matrix("F",M)
mat G = B,C,D,E,F
mata: M = colshape(st_matrix("R"),2)
mata: st_matrix("R",M)
mat R = R'
mat li R
matrix colnames R = "Ps R2" "LR chi2" "p>chi2" "MeanBias" "MedBias" "B" "R" "%Var"
matrix rownames R = "Unmatched" "Matched"
matrix colnames G = "Treated" "Control" "%bias" "%red_bias" "t" "p>|t|" "V(T)/V(C)"
matrix rownames G = "foreign (U)" "foreign (M)" "alcohol (U)" "alcohol (M)" "mage (U)" ///
"mage (M)" "medu (U)" "medu (M)" "fage (U)" "fage (M)" "fedu (U)" "fedu (M)"
estout mat(G, fmt(3))
mat li R, format(%4.3f)
qui psmatch2 mbsmoke foreign alcohol mage medu fage fedu, out(bweight) logit n(5) ai(5) ate common
pstest, both atu

Answer 1

I'm currently using some matching techniques and had the same question. One shortcut I found is using 'asdoc'.
I used:
"asdoc pstest v1 v2 v3"
asdoc created a word document called myfile in your working directory and from there you might take the table and transform into latex maybe. I haven't found a better way yet, but thought if it comes handy to you somehow.
Good luck with your work! :)