Google Sheet: Horizontal Consecutive Query Outputs - google-sheets

Question

I have a set of data that looks like the following:
Faculty (A)
Course Name (B)
Course Description (C)
Units (D)
John Doe
Math 101
Intro to Math
2 Units
John Doe
Math 102
Intermediate Math
3 Units
Jane Doe
Physics 101
Intro to Physics
4 Units
I'm trying to create a query function that organizes the data on another sheet in the following way:
Faculty (A)
Course Name 1(B)
Course Desc 1(C)
Unit Count 1(D)
Course Name 2(E)
Course Desc 2(F)
Unit Count 2(G)
John Doe
Math 101
Intro to Math
2 Units
Math 102
Intermediate Math
3 Units
Jane Doe
Physics 101
Intro to Physics
4 Units
Above is how I picture this theoretically. Here is an actual link to as sheet that shows a little closer to what I'm working with: https://docs.google.com/spreadsheets/d/18ucJ7QQx39STKSm6EqH2yYkHd5AjZNlJxIwpQ9kGXdw/edit#gid=2020540687
Any help with this would be appreciated!

Answer 1

use:
=ARRAYFORMULA(IFERROR(SPLIT(FLATTEN(QUERY(TRANSPOSE(QUERY(QUERY(
{A2:A, "×"&B2:B&"×"&C2:C&"×"&D2:D, B2:B&C2:C&D2:D},
"select Col1,max(Col2) where Col1 is not null group by Col1 pivot Col3"),
"offset 1", 0)),,9^9)), "×")))

Answer 2

This is a challenge to get unstructured data to align correctly, but I think this may be the way to do it. It is a little complicated, but for each set of 'Course Name/Course Description/Units' it requires a QUERY. Please test it on a larger set of data. I came across issues relating to unsorted source data. For testing, I suggest you name the 'Units' the same as 'Faculty' so you can see if the 'Faculty' names line across correctly.
Relative to your 4 columns of source data (A:D), this goes in cell F1:
=query(ARRAYFORMULA({countif(A1:A,A:A),COUNTIFS($A1:$A,$A1:$A,ROW($A1:$A),"<="&ROW($A1:$A)),$A:$D}),"select Col3,Col4,Col5,Col6 where Col2=1 order by Col1 desc,Col3,Col2 label Col3 'Faculty', Col4 'Course Name 1',Col5 'Course Description 1',Col6 'Units 1'",1)
The other columns don't repeat 'Faculty' so the QUERY is slightly different. Notice where Col2=2 changes... 3 for the 3rd set, 4 for the 4th set etc.
Also note that the data needs to be sorted by 'faculty with most courses' so that subsequent rows don't collapse.
In cell J1:
=query(ARRAYFORMULA({countif(A1:A,A:A),COUNTIFS($A1:$A,$A1:$A,ROW($A1:$A),"<="&ROW($A1:$A)),$A:$D}),"select Col4,Col5,Col6 where Col2=2 order by Col1 desc,Col3,Col2 label Col4 'Course Name 2',Col5 'Course Description 2',Col6 'Units 2'",1)
In cell M1:
=query(ARRAYFORMULA({countif(A1:A,A:A),COUNTIFS($A1:$A,$A1:$A,ROW($A1:$A),"<="&ROW($A1:$A)),$A:$D}),"select Col4,Col5,Col6 where Col2=3 order by Col1 desc,Col3,Col2 label Col4 'Course Name 3',Col5 'Course Description 3',Col6 'Units 3'",1)
In cell P1:
=query(ARRAYFORMULA({countif(A1:A,A:A),COUNTIFS($A1:$A,$A1:$A,ROW($A1:$A),"<="&ROW($A1:$A)),$A:$D}),"select Col4,Col5,Col6 where Col2=4 order by Col1 desc,Col3,Col2 label Col4 'Course Name 4',Col5 'Course Description 4',Col6 'Units 4'",1)
In cell S1:
=query(ARRAYFORMULA({countif(A1:A,A:A),COUNTIFS($A1:$A,$A1:$A,ROW($A1:$A),"<="&ROW($A1:$A)),$A:$D}),"select Col4,Col5,Col6 where Col2=5 order by Col1 desc,Col3,Col2 label Col4 'Course Name 5',Col5 'Course Description 5',Col6 'Units 5'",1)