I am currently trying to make a google sheets where Column A is a Date and Column B,C,D,E Are relevant info according to that date. I am wondering how it is possible to highlight cells B-E in the same row if two criteria are met:
If column A of that row is not blank.
If any cell in B-E is blank to highlight them red.
Basically it is a way for showing there should be data there if there is a data (A date) in column A. I can do this for a single row, but I cant find a way to apply this to all of the sheet until the EOF.
Thanks,
Example of single row:
Use custom formula for CF:
=SUMPRODUCT(($A2<>"")*($B2:$E2=""))
apply formatting to B2:E
References
SUMPRODUCT
Google Sheets conditional formatting
Related
I have a Google sheet that has a roster of people. I want the sheet to automatically color code people on the roster tab that are also present on a second tab that lists people who have dietary restrictions. I thought that conditional formatting would be the way to go, but I can't get the formula to work. I also can seem to get the conditional formatting formula to be relative based on the row. This is the formula that I have so far. A5 is the first cell that contains the person's ID number. The ID numbers are listed in column A on the "Dietary Restrictions" sheet.
=NOT(ISNA(VLOOKUP(A5,'Ghost Students'!A:H,1,FALSE)))
You want to highlight values from A5:A in one sheet (let's call it Roster) if they are present in column A from another sheet (Dietary restrictions).
Since conditional formatting formulas cannot reference other sheets, you have to use INDIRECT in order to reference that.
You can then use MATCH to check if the value is present.
Your formula could be like this:
=MATCH($A5,INDIRECT("'Dietary restrictions'!A2:A"),0)
Output:
Sheet Roster:
Sheet Dietary restrictions:
How about making vlookup formula grabbing data about dietary conditions from another sheet, and then putting conditional formatting.
You can hide information about dietary conditions if you want and apply conditional formatting based on hidden column:
Just tried. Conditional formatting works with hidden columns too.
Struggling with this one.
I have a sheet with columns A to GC with dates in random places. I need conditional formatting to highlight an entire row if the date in that row is today.
I've got this formula =match(today(),$A1:$GC1) which works on a test sheet (a blank google sheet with a date in a random place) but when applying this to the sheet I need it at, it doesn't work. Just highlights everything for some reason.
Copy of the Google sheet: Sample Sheet
It seems like the existing values in your sheet are messing with the conditional formatting. Try using COUNTIF instead:
=COUNTIF($A1:$GC1, TODAY())
Reference:
COUNTIF
I've created a list of Foods in a Google Sheet.
On another sheet I reference A2:A100 to create a data validation list to select from.
I am trying to figure out how to auto-fill the equivalent columns on the other sheet depending on which food is selected but the value in the data validation list is simply text, so I cannot figure out how to get the row it is on to transfer the values onto the new sheet.
This is what I have right now:
This is what I am trying to get it to look like:
If I change any of the foods, I want columns B - H to automatically fill in with the correct values from the Foods sheet.
How can I do this?
You can use couple of methods
Using DGET
=IFERROR(ArrayFormula(DGET('Foods'!$A$1:$K$100,{"calories","sat","poly","mono","fiber","carbs","protein"},{"Food";$A2})))
OR
=IFERROR(ArrayFormula(DGET('Foods'!$A$1:$K$100,{$B$1,$C$1,$D$1,$E$1,$F$1,$G$1,$H$1},{"Food";$A2})))
Using VLOOKUP
=IFNA(ArrayFormula(VLOOKUP($A2,'Foods'!$A$1:$K$100,{5,6,7,8,9,10,11},FALSE)))
Place the formula on cell B1 and drag down.
Functions used:
DGET
ArrayFormula
IFERROR
VLOOKUP
IFNA
That's simple i know that =Sheet1!B2 but if i add row above the B2. formulas automatically change to B3. I can write code google apps script but i need to do it with formula. By the way add row automatically specific time.
I want it to stay constant B2
In my testing it would be:
=INDIRECT("Sheet1!B2")*K2
The "Indirect" function returns a cell reference by a string, so the helpful google sheets can't change it by adding new rows.
I'm making a spreadsheet on google docs, listing prices of different products from different sources.
Then I want to compare each of the product's price and format the cell background color where the product is cheaper (my real problem here).
For now, it has 3 columns (B, D and F), from row 3 up to 18.
Each row is a product, and each column is a different "store".
I have searched for 2 hours now and I can't find anything close to this. Every question I found is about comparing an array to a single cell, not row to row, including multiple columns.
Is there a simple function or custom formula to do this?
Please try clearing formatting from and selecting ColumnsB:F and Format, Conditional formatting..., Format cells if... Custom formula is and:
=and(B1<>"",B1=min($B1,$D1,$F1))
Then select formatting of choice and Done.