NSIS. Post russian text with inetc plugin - post

Question

I'm writing custom uninstaller feedback window. There are radiobutton with default reasons and textfield, where users write their own uninstall reason. I replace default reason with string constant and post it without any problems. If i send english text from textfield, it works. But not the russian. Server send error 500 and can't encode my data. How to pass data on russian in right way?
I'm build Unicode installer. Server expect UTF-8 data.
$reason_edit_data - text from textfield
$CB_#_State - state of # radiobutton (checked/unchecked)
; **REPLACE DEFAULT REASON WITH STRING CONSTANT**
StrCpy $reason "NO_DEFAULT_REASON"
${If} $CB_1_State == ${BST_CHECKED}
StrCpy $reason "CANT_FIGURE_OUT"
${EndIf}
${If} $CB_2_State == ${BST_CHECKED}
StrCpy $reason "FAILED_WITH_PLUGINS"
${EndIf}
${If} $CB_3_State == ${BST_CHECKED}
StrCpy $reason "ERRORS_IN_APP"
${EndIf}
${If} $CB_4_State == ${BST_CHECKED}
StrCpy $reason "SUB_USE_WEB"
${EndIf}
${If} $CB_5_State == ${BST_CHECKED}
StrCpy $reason "REINSTALL_APP"
${EndIf}
; **COPY TEXTFIELD DATA TO VARIABLE. PROBLEM WITH COMMENT**
${If} $reason_edit_data == ""
StrCpy $comment "NO_EXTRA_REASON"
${Else}
StrCpy $comment "$reason_edit_data"
${EndIf}
; **POST DATA. HEADER JUST FOR EXAMPLE**
inetc::post '{ "reason": "$reason", "comment": "$comment" }' \
/TOSTACKCONV \
/SILENT \
/HEADER
"https://api.example.com/api/uninstallations" \
/END
Pop $0
MessageBox MB_OK "status: $0"

Answer 1

INetC is limited to UTF-16LE and the active Ansi codepage. A /UTF8DATA switch could probably be added but in the meantime you have to put the post data in a file:
!include LogicLib.nsh
Function WriteStringAsUTF8ToFile
Exch $1 ; File path
Exch
Exch $2 ; NSIS string & File handle
Push $0
Push $3 ; UTF-8 string buffer
System::Call 'KERNEL32::WideCharToMultiByte(i65001,i0,wr2,i-1,p0,i0,p0,p0)i.r0'
${If} $0 = 0
fail_simple:
StrCpy $1 ""
${Else}
System::Call '*(&i$0)p.r3'
${IfThen} $3 P= 0 ${|} Goto fail_simple ${|}
System::Call 'KERNEL32::WideCharToMultiByte(i65001,i0,wr2,i-1,pr3,ir0,p0,p0)'
IntOp $0 $0 - 1 ; Don't write the terminator
FileOpen $2 $1 w
${IfThen} $2 == "" ${|} Goto fail ${|}
System::Call 'KERNEL32::WriteFile(pr2,pr3,ir0,*i,p0)i.r0'
${IfThen} $0 = 0 ${|} StrCpy $1 "" ${|}
FileClose $2
Goto done
fail:
StrCpy $1 ""
done:
System::Free $3
${EndIf}
Pop $3
Pop $0
Pop $2
Exch $1
FunctionEnd
Section
InitPluginsDir
Push "${U+2115}SIS" ; String to write as UTF-8
Push "$PluginsDir\data.txt"
Call WriteStringAsUTF8ToFile
Pop $0
${If} $0 == ""
MessageBox mb_ok "Error: Unable to write post data to file!"
${Else}
inetc::post $0 /FILE /TOSTACK "http://example.com/post" "" /END
Pop $1 ; "OK" on success
Pop $2
MessageBox mb_ok "Result: $1$\nResponse: $2"
${EndIf}
SectionEnd