Call a child class method when setting the base class property [closed] - delphi

Question

Closed. This question needs details or clarity. It is not currently accepting answers.
Want to improve this question? Add details and clarify the problem by editing this post.
Closed 2 years ago.
Improve this question
I'm creating custom components. This custom component is inherited from TControl which have a TAlign property. I want to execute a method from my descending classes whenever TAlign is set a value
This is the draft of the descending class:
TWidget = class(TControl)
public
procedure Resize;
end;
When I write a value to TAlign (From TControl class), another method, from TWidget is called. Like so:
var
t: TWidget;
begin
t := TWidget.Create(Self);
t.Align := alRight; // When this is executed, "Resize" from TWidget should be called

Answer 1

When a control's Align property is changed, it calls the control's SetBounds() and RequestAlign() methods.
SetBounds() is virtual, so a descendant can override it directly. This is also the same method that is called by the control's Left, Top, Width, and Height property setters. After applying the new bounds, SetBounds() issues a WM_WINDOWPOSCHANGED message to the control (which can be caught by override'ing the control's virtual WndProc() method, or by subclassing its WindowProc property, or by declaring a message handler), as well as calls the RequestAlign() and Resize() methods.
RequestAlign() calls Parent.AlignControl(), which does a lot of work, but it basically boils down to simply repositioning each of the Parent's visible child controls relative to each other based on their respective Align and Anchors values. Those repositions are done by calling SetBounds() on each child control.
Resize() just fires the control's OnResize event handler, if assigned.
So, the best way to have your custom control react to changes in its size or position is to simply override its SetBounds() method, or handle the WM_WINDOWPOSCHANGED message, eg:
type
TWidget = class(TControl)
public
procedure SetBounds(ALeft, ATop, AWidth, AHeight: Integer); override;
end;
procedure TWidget.SetBounds(ALeft, ATop, AWidth, AHeight: Integer);
begin
inherited SetBounds(ALeft, ATop, AWidth, AHeight);
// use Left/Top/Width/Height properties as needed...
end;
Or:
type
TWidget = class(TControl)
protected
procedure WndProc(var Message: TMessage); override;
end;
procedure TWidget.WndProc(var Message: TMessage);
begin
inherited WndProc(Message);
if Message.Msg = WM_WINDOWPOSCHANGED then
begin
// use Left/Top/Width/Height properties as needed...
end;
end;
Or:
type
TWidget = class(TControl)
private
procedure WMWindowPosChanged(var Message: TWMWindowPosChanged); message WM_WINDOWPOSCHANGED;
end;
procedure TWidget.WMWindowPosChanged(var Message: TWMWindowPosChanged);
begin
inherited;
// use Left/Top/Width/Height properties as needed...
end;