Parse Url querystring with delphi 5 - parsing

Question

I have this string:
Called=%2B12608883475&ToState=IN&CallerCountry=US&Direction=inbound&CallerState=IN&ToZip=&CallSid=CAb7faaa30058c2347a595630f2475113a&To=%2B12608883475&CallerZip=
I would like to parse it by & to get all the parameters out and then sort the parameters in an alphabetical case-sensitive order.
All of this has to be done in Delphi 5:
Function TwilioSignatureValidate(twilioSignature: string; QueryString: string ; Url: string): boolean;
begin
parameters := QueryString;
List := TStringList.Create;
end;
Here is the C# version that I want to copy:
string input = "Called=%2B12608883475&ToState=IN&CallerCountry=US&Direction=inbound&CallerState=IN&ToZip=&CallSid=CAb7faaa30058c2347a595630f2475113a&To=%2B12608883475&CallerZip=";
Dictionary<string,string> keyValuePairs = input.Split('&')
.Select(value => value.Split('='))
.ToDictionary(pair => pair[0], pair => pair[1]);
string studentId = keyValuePairs["StudentId"];
Using List.Sort;
I got my Delphi List To sort alphebetically but its not in using Unix-style case-sensitive sorting order:
//Delphi Sort
https://ffbc1360.ngrok.io
AccountSidACc6d06b4cb61ccbfa61bf461957a5a626
ApiVersion2010-04-01
Called+12608883475
CalledCity
CalledCountryUS
CalledStateIN
CalledZip
Caller+12602060582
CallerCity
CallerCountryUS
CallerStateIN
CallerZip
CallSidCAb7faaa30058c2347a595630f2475113a
CallStatusringing
Directioninbound
From+12602060582
FromCity
FromCountryUS
FromStateIN
FromZip
To+12608883475
ToCity
ToCountryUS
ToStateIN
ToZip
//Correct c# Sort
https://ffbc1360.ngrok.io
AccountSidACc6d06b4cb61ccbfa61bf461957a5a626
ApiVersion2010-04-01
CallSidCAb7faaa30058c2347a595630f2475113a
CallStatusringing
Called+12608883475
CalledCity
CalledCountryUS
CalledStateIN
CalledZip
Caller+12602060582
CallerCity
CallerCountry
USCaller
StateIN
CallerZip
Directioninbound
From+12602060582
FromCity
FromCountryUS
FromStateIN
FromZip
To+12608883475
ToCity
ToCountryUS
ToStateIN
ToZip

Answer 1

TStringList in Delphi 6 and later has Delimiter, DelimitedText, and CaseSensitive properties. Set the Delimiter to '&' and then assign the query string to DelimitedText, then you can use the Values[] property to extract values by name (since the resulting delimited strings are already in name=value format). No sorting is needed:
Function TwilioSignatureValidate(twilioSignature: string; QueryString: string ; Url: string): boolean;
var
List: TStringList;
begin
List := TStringList.Create;
try
List.Delimiter := '&';
List.DelimitedText := QueryString;
List.CaseSensitive := True;
// use List.Values['param name'] as needed, eg:
// List.Values['Called']
// List.Values['ToState']
// List.Values['CallerCountry']
// List.Values['Direction']
// List.Values['CallerState']
// List.Values['ToZip']
// List.Values['CallSid']
// List.Values['To']
// List.Values['CallerZip']
finally
List.Free;
end;
end;
However, in Delphi 5, none of those properties existed yet, so you will have to do everything manually:
Function TwilioSignatureValidate(twilioSignature: string; QueryString: string ; Url: string): boolean;
var
List: TStringList;
// the following are tweaked from TStrings in later Delphi versions...
procedure MySetDelimitedText(const Value: string);
var
P, P1: PChar;
S: string;
begin
List.BeginUpdate;
try
List.Clear;
P := PChar(Value);
while P^ <> #0 do
begin
if P^ = '"' then
S := AnsiExtractQuotedStr(P, '"')
else
begin
P1 := P;
while (P^ <> #0) and (P^ <> '&') do
P := CharNext(P);
SetString(S, P1, P - P1);
end;
List.Add(S);
if P^ = '&' then
begin
P := CharNext(P);
if P^ = #0 then
List.Add('');
end;
end;
finally
List.EndUpdate;
end;
end;
function MyIndexOfName(const Name: string): Integer;
var
P: Integer;
S: string;
begin
for Result := 0 to List.Count - 1 do
begin
S := List.Strings[Result];
P := AnsiPos('=', S);
if (P <> 0) and (AnsiCompareStr(Copy(S, 1, P - 1), Name) = 0) then Exit;
end;
Result := -1;
end;
function MyGetValue(const Name: string): string;
var
I: Integer;
begin
I := MyIndexOfName(Name);
if I >= 0 then
Result := Copy(List.Strings[I], Length(Name) + 2, MaxInt) else
Result := '';
end;
begin
List := TStringList.Create;
try
MySetDelimitedText(QueryString);
// use MyGetValue('param name') as needed, eg:
// MyGetValue('Called')
// MyGetValue('ToState')
// MyGetValue('CallerCountry')
// MyGetValue('Direction')
// MyGetValue('CallerState')
// MyGetValue('ToZip')
// MyGetValue('CallSid')
// MyGetValue('To')
// MyGetValue('CallerZip')
finally
List.Free;
end;
end;