How to make ARRAYFORMULA work with SUMIFS? - google-sheets

Question

I have a SUMIFS formula that works fine, but I have to drag it down to populate every column, which is quite impractical for the amount of data I have in my spreadsheet, therefore I want to turn it into an ARRAYFORMULA. The formula is supposed to calculate how many of a product was purchased in a month. It currently looks like this:
=SUMIFS(All!$N$3:$N, All!$AG$3:$AG, ">=1/1/2018", All!$AG$3:$AG, "<=31/1/2018", All!$L$3:$L, $A2)
All!N contains the quantity of an item the customer purchased, All!AG contains the date, and All!L contains the product code which is checked against the product code in column A.
I tried simply doing
=ARRAYFORMULA(SUMIFS(All!$N$3:$N, All!$AG$3:$AG, ">=1/1/2018", All!$AG$3:$AG, "<=31/1/2018", All!$L$3:$L, $A$2:$A))
but that only works for cell A2 - it just prints the same result as the other formula and doesn't carry on down the column, which is what I want it to do. That solution worked with a SUMIF formula I have (it does the same thing but doesn't check the date) but it won't work with SUMIFS. I'm not sure why and I'm not the best at troubleshooting these spreadsheet formulas so I'm hoping someone can help.
Update: Here is a dummy sheet showing the issue: https://docs.google.com/spreadsheets/d/1pX-icbJxmy8A0jhKLnSRxhZTLRgYFG_iU2BOQrseCCg/edit?usp=sharing

Answer 1

paste in B2 cell:
=ARRAYFORMULA(IF(LEN($A$2:$A), IFERROR(VLOOKUP($A$2:$A,
QUERY({All!$B$3:$D},
"select Col1, sum(Col2)
where Col3 is not null
group by Col1
label sum(Col2)''", 0), 2, 0), 0), ))
paste in C2 cell and drag to the right:
=ARRAYFORMULA(IF(LEN($A$2:$A), IFERROR(VLOOKUP($A$2:$A,
QUERY({All!$B$3:$D},
"select Col1, sum(Col2)
where Col3 >= date '"&TEXT( C$1, "yyyy-mm-dd")&"'
and Col3 <= date '"&TEXT(EOMONTH(C$1, 0), "yyyy-mm-dd")&"'
group by Col1
label sum(Col2)''", 0), 2, 0), 0), ))
spreadsheet demo