Creating relationships based on nested list - neo4j

Question

I'm building a graph based and some of the relationships are based on information in nested lists. The relevant nodes are (b:Bundle) and (o:Object); the bundles require certain objects with different quantities and qualities. The nested list that contains these requirements has the format [ [object1, quantity1, quality1], [object2, quantity2, quality2], ... ]
but in the .csv file that I'm using the field has the format
o1,qn1,ql1|o2,qn2,ql2|... The relationship I want to create is
(b)-[r:REQUIRES {quantity, quality}]->(o).
I've tried using various combinations of SPLIT, UNWIND, and FOREACH. A minimal example from my data set:
id: 1
requirements: 24,1,0|188,1,0|190,1,0|192,1,0
That is to say, (b:Bundle {id:1}) -[r:REQUIRES {quantity:1, quality:0}]-> (o:Object {id:24}) and so on.
LOAD CSV WITH HEADERS FROM 'file:///bundles.csv' AS line
WITH SPLIT( UNWIND SPLIT ( line.requirements, '|' ), ',') as reqList
MATCH ( o:Object { id:TOINTEGER(reqList[0]) } )
MATCH ( b:Bundle { id:TOINTEGER(line.id) } )
MERGE (b) -[r:REQUIRES]-> (o)
ON CREATE SET r.quantity = TOINTEGER(reqList[1]),
r.quality = TOINTEGER(reqList[2]);
The error this query gives is
Neo.ClientError.Statement.SyntaxError: Invalid input 'P': expected 't/T' (line 2, column 22 (offset: 78))
" WITH SPLIT( UNWIND SPLIT ( line.requirements, '|' ), ',') as reqList"
^

Answer 1

Assuming your CSV file actually looks like this:
id requirements
1 24,1,0|188,1,0|190,1,0|192,1,0
then this query should work:
LOAD CSV WITH HEADERS FROM 'file:///bundles.csv' AS line FIELDTERMINATOR ' '
WITH line.id AS id, SPLIT(line.requirements, '|' ) AS reqsList
UNWIND reqsList AS reqsString
WITH id, SPLIT(reqsString, ',') AS reqs
MATCH ( o:Object { id:TOINTEGER(reqs[0]) } )
MATCH ( b:Bundle { id:TOINTEGER(id) } )
MERGE (b) -[r:REQUIRES]-> (o)
ON CREATE SET r.quantity = TOINTEGER(reqs[1]),
r.quality = TOINTEGER(reqs[2]);