Use QUERY to get Avg of last x entries matching conditions - google-sheets

Question

I'm trying to refine my coding for a working spreadsheet by updating all the code to QUERY functions. One thing I am stuck on is where I average the last x rows matching specific conditions.
I was hoping that the following formula would work:
=QUERY(Ladder!A2:AE,"Select Avg(J) where F = '"&H$1&"' order by B desc limit "&$C$5)
My thought being that this would return the average of the last 3 rows - but I receive the
COL_IN_ORDER_MUST_BE_IN_SELECT error.
I only want the formula to return a single cell with the % average in it.
I realise that I could use the following code and then QUERY the Avg of that, but I want to be able to return % values for each different deck.
Here's a link to a cut down version of the spreadsheet:
Spreadsheet
Ladder: Where I enter the data
Ladder Filter: Where the data will filter based on query commands depending on criteria in the Ladder Stats tab
Ladder Stats: Where I can view all statistics and generate various statistical reports
It's all working at the moment, but as you can see it's very clunky and formula-heavy. I've worked most of it out except for the scenario you will find on the "Ladder Stats" tab - whereby B3="" and C5 != NULL. It is designed to give statistics for the last x games played by each of the decks.

Answer 1

you can either use a double query like this and format cell as %
=QUERY(QUERY(Ladder!A2:AE,
"select J
where F = '"&H$1&"'
order by B desc
limit "&$C$5, 0),
"select avg(Col1)
label avg(Col1)''", 0)
or you can use AVERAGE formula and click twice to get decimal position:
=AVERAGE(QUERY(Ladder!A2:AE,
"select J
where F = '"&H$1&"'
order by B desc
limit "&$C$5, 0))