Stuck after ~500 inserts - neo4j

Question

I am inserting nodes and relations into my neo4j DB (graphenedb but also happens locally).
After roughly 500 inserts the insert statment stucks.
After a neo4j server restart, the same insert works as usual and I can continue with the next ~500 inserts.
Do you have any clue why it get stuck?
One insert statement looks like following:
MERGE (b0:Company{company_id:{b1},universal_name:{b2},company_name:{b3}})
ON CREATE SET b0.funding_total_usd = null
ON MATCH SET b0.funding_total_usd = null
MERGE (b13:Industry{name:{b12}})
MERGE (b0)-[:company_industry]->(b13)
MERGE (b15:Category{name:{b14}})
MERGE (b0)-[:company_category]->(b15)
MERGE (b17:Category{name:{b16}})
MERGE (b0)-[:company_category]->(b17)
MERGE (b19:Category{name:{b18}})
MERGE (b0)-[:company_category]->(b19)
MERGE (b21:Category{name:{b20}})
MERGE (b0)-[:company_category]->(b21)
MERGE (b23:Category{name:{b22}})
MERGE (b0)-[:company_category]->(b23)
MERGE (b25:Category{name:{b24}})
MERGE (b0)-[:company_category]->(b25)
MERGE (b27:Category{name:{b26}})
MERGE (b0)-[:company_category]->(b27)
Indexes are present:
Indexes
ON :Category(name) ONLINE (for uniqueness constraint)
ON :Company(company_id) ONLINE (for uniqueness constraint)
ON :Company(universal_name) ONLINE (for uniqueness constraint)
ON :Industry(name) ONLINE (for uniqueness constraint)
Constraints
ON ( category:Category ) ASSERT category.name IS UNIQUE
ON ( company:Company ) ASSERT company.company_id IS UNIQUE
ON ( company:Company ) ASSERT company.universal_name IS UNIQUE
ON ( industry:Industry ) ASSERT industry.name IS UNIQUE
I use following PHP code to submit the statement:
$config = \GraphAware\Bolt\Configuration::create()
->withCredentials($user, $pw)
->withTimeout($timeout);
if($ssl) {
$config = $config->withTLSMode(\GraphAware\Bolt\Configuration::TLSMODE_REQUIRED);
}
$driver = \GraphAware\Bolt\GraphDatabase::driver($uri, $config);
$driver->session()->run($query, $binds);
Tested versions: 3.4.12 and 3.5.1
#edit: Added code which is used to submit the statement and neo4j version.

Answer 1

You should be batching your insertions, and you should not be explicitly creating separate variables for each individual node. Instead, see if you can provide parameters which include lists of properties that you can address at a single time using UNWIND.
See some of our batching tips and tricks.
Applied to your query, your parameter input per batch could look something like this:
{entries:[{companyId:12345, universalName:'foo', companyName:'bar',
industry:'industry', categories:[{name:'cat1'}, {name:'cat2'},
{name:'cat3'}]}]}
And the query itself per batch execution could look like this:
UNWIND $entries as entry
MERGE (c:Company{company_id:entry.companyId, universal_name:entry.universalName, company_name:entry.companyName})
SET c.funding_total_usd = null
MERGE (industry:Industry{name:entry.industry})
MERGE (c)-[:company_industry]->(industry)
WITH entry, c
UNWIND entry.categories as cat
MERGE (category:Category{name:cat.name})
MERGE (c)-[:company_category]->(category)