select first day of month in google sheets query - google-sheets

Question

I am trying to construct a query that would among other columns return a date, which is in column J of an "rawData" table and change this date to the first day of month.
In my query all date statements but the last one are for testing purposes. The last one causes an error (Unknown range name: 'J'.). Anybody knows where is the mistake? This is my query:
=query(rawData;"select C, YEAR(J), MONTH(J)+1,
date'2010-08-31',
date '"&TEXT(2010-10-1;"yyyy-mm-dd")&"',
date '"&TEXT(CONCATENATE("2020-12";"-01");"yyyy-mm-dd")&"',
date '"&TEXT(CONCATENATE(YEAR(J);"-";MONTH(J);"-01");"yyyy-mm-dd")&"',
SUM(L)
WHERE (C<>'')
AND (F=18 OR F=20 OR F=62)
group by C, YEAR(J), MONTH(J)+1";1
)
Thanks,
Andrej

Answer 1

First, refer the documentation for the Query Language Reference, particular the use of [Scalar Functions] (https://developers.google.com/chart/interactive/docs/querylanguage#scalar-functions). The options here are very limited and do not appear to permit the calculation of the 'first of the month' within the query, per se.
It is possible to build the 'first of the month' within the rawData sheet, and I'll demonstrate the process, but I'll think you will agree that it doesn't achieve any perceivable advantage.
Try this.
Helper Column P
1) Create a helper column "P" in rawData. In cell P2, enter this formula:
=arrayformula(IF(ISBLANK(J2:J);"";DATE(Year(J2:J);Month(J2:J);1)))
Select the entire column and format it as Date 'yyyy-mm-dd'.
This is your "first of the month date". For identification, enter "Date yyyy-mm-dd" in Cell P1.
Query#1
2) Create a new sheet for testing. In cell A1 enter this formula:
=query(rawData!A2:P;"Select C, sum(L) WHERE (C<>'') AND (F=18 OR F=20 OR F=62) group by C label C 'Reg_st_vozila',sum(L) 'Total'").
This is the product code and sum by quantity, grouped by Product Code; you should have 24 records.
Query#2
3) In the same new sheet, in cell D1 enter this formula
=query(rawData!A2:P;"Select C, P, sum(L) WHERE (C<>'') AND (F=18 OR F=20 OR F=62) group by C,P label C 'Reg_st_vozila', P 'Date', sum(L) 'Total'")
This is the product code and sum by quantity, grouped by Product Code and First of the Month date (the date from the Helper Column). You should have 1142 records.
Query#3
4) In the same new sheet, in cell H1 enter this formula:
=query(rawData!A2:P;"Select C, Year(J), Month(J)+1, sum(L) WHERE (C<>'') AND (F=18 OR F=20 OR F=62) group by C,Year(J),Month(J)+1 label C 'Reg_st_vozila', Year(J) 'Year', Month(J)+1 'Month', sum(L) 'Total'")
This is the product code and sum by quantity, grouped by Product Code by Year by Month date. You should have 1142 records.
The output is identical to the preceding formula, though the query has an extra field (one for Year, one for Month). My point is that the 'first of month' doesn't achieve anything special.
Helper Column Q
5) Create a second helper column "Q" in rawData. In cell Q2, enter this formula:
=arrayformula(J2:J)
Select the entire column and format it as Date 'yyyy-mm'.
This is a modification of the date column, but formatted for year-month.
For identification, enter "Date yyyy-mm" in Cell Q1.
Query#4
6) In the new query sheet, in cell M1 enter this formula:
=query(rawData!A2:Q;"Select C, Q, sum(L) WHERE (C<>'') AND (F=18 OR F=20 OR F=62) group by C,Q label C 'Reg_st_vozila', Q'Year/Month', sum(L) 'Total'")
This is the product code and sum by quantity, grouped by Product Code by Year & Month. You should have 1142 records.
The output is identical to Query#2 but without the aggravation of calculating the "first of the month. Again, it shows that grouping on 'fom' doesn't achieve any perceivable advantage.