Comparing values in different rows to create new variable - spss

Question

I have a dataset that looks like this:
outlet name (string variable): name of media outlet (maximum 12), the last three outlets in the file are The Guardian, The Telegraph and The Independent.
score 1: scale
score 2: scale
...
score 7: scale.
What I want to do is compute a set of 21 new variables that show for each of the cases (media outlets), for each of the seven variables (scores), the difference between the score of that specific outlet, and the scores of the three outlets of interest: The Guardian, The Telegraph and The Independent (7 variables X 3 benchmark outlets=21). Essentially I want to compare each outlet's scores to my three benchmark outlets.
So for example I should have a new variable, named score1_Guardian, that for outlet 1 will be computed as: the score outlet 1 got for that variable - the score The Guardian got for that variable. Variable score2_Guardian will show, for each outlet, the difference between the score each specific outlet got on that variable and the score The Guardian got for that variable, and so on. So in this example, the outlet The Guardian will score 0 on all score1_Guardian to score7_Guardian variables.

Answer 1

There are simpler ways to do this than what I suggest below, but I like it better this way - less code and less temporary variables.
First I create a fake dataset according to your parameters:
data list list/outlet (a12) score1 to score7 (7f6).
begin data
'outlet1' 1 2 3 4 5 6 7
'outlet2' 2 3 4 5 6 7 8
'outlet3' 5 6 7 8 9 1 2
'Guardian' 7 8 9 1 2 5 6
'Telegraph' 5 12 12 3 4 4 2
'Independent' 2 2 2 2 2 2 2
end data.
Now we can get to work:
*going from wide to long form - just to avoid creating too many variables on the way.
varstocasese /make score from score1 to score7/index scorenum(score).
if outlet='Guardian' Guardian=score.
if outlet='Telegraph' Telegraph=score.
if outlet='Independent' Independent=score.
AGGREGATE /OUTFILE=* MODE=ADDVARIABLES OVERWRITEVARS=YES
/BREAK=scorenum /Guardian=MAX(Guardian) /Telegraph=MAX(Telegraph) /Independent=MAX(Independent).
*now we have three new variables ready to compare.
compute Guardian=score - Guardian.
compute Telegraph=score - Telegraph.
compute Independent=score - Independent.
* last step - going back to wide format.
compute scorenum=substr(scorenum,6,1).
CASESTOVARS /id=outlet /index=scorenum/sep="_".