How can I select a Tab in TTabControl from a right click - delphi

Question

I have a popup menu associated with my TTabControl. I want to be able select the tab and invoke the drop down in one Right Hand button click. Other controls I seem to remember would have a right button select property.

Answer 1

You can use the OnPopup event handler of your TPopupMenu:
procedure TForm1.PopupMenu1Popup(Sender: TObject);
var
TabIndex : integer;
Pt : TPoint;
begin
Pt := TabControl1.ScreenToClient(TPopupMenu(Sender).PopupPoint);
TabIndex := TabControl1.IndexOfTabAt(Pt.X, Pt.Y);
if(TabIndex <> -1) then
begin
TabControl1.TabIndex := TabIndex;
end;
end;

Answer 2

You can do something like this:
type
TTabControl = class(Vcl.ComCtrls.TTabControl)
private
FRightClickSelect: Boolean;
procedure CNNotify(var Msg: TWMNotify); message CN_NOTIFY;
public
constructor Create(AOwner: TComponent); override;
published
property RightClickSelect: Boolean read FRightClickSelect write FRightClickSelect default False;
end;
implementation
uses
Winapi.CommCtrl;
{ TTabControl }
constructor TTabControl.Create(AOwner: TComponent);
begin
inherited;
FRightClickSelect := False;
end;
procedure TTabControl.CNNotify(var Msg: TWMNotify);
var
Index: Integer;
HitInfo: TTCHitTestInfo;
begin
if FRightClickSelect and (Msg.NMHdr.code = NM_RCLICK) then
begin
HitInfo.pt := ScreenToClient(Mouse.CursorPos);
Index := SendMessage(Handle, TCM_HITTEST, 0, LPARAM(#HitInfo));
if (Index <> -1) and (HitInfo.flags <> TCHT_NOWHERE) then
TabIndex := Index;
end;
inherited;
end;