TVirtualStringTree - setting column cells/nodes Alignment - delphi

Question

I have a VirtualStringTree with a Header.Column set to taLeftJustify (default).
Is there a way to set the cells/nodes of that column to taRightJustify so that the nodes will be justified to the right, but the header column text will be justified to the left?
This is my desired result (in column 1):
I'm using a rather old VT version 4.5.5

Answer 1

For Column caption alignment use:
Header.Columns[x].CaptionAlignment := taLeftJustify;
and for nodes alignment:
Header.Columns[x].Alignment := taRightJustify;
x = your column

Answer 2

In my old VT version, there is no TVirtualTreeColumn.CaptionAlignment, so I managed to use OnAdvancedHeaderDraw to draw my own columns captions. I set column 1 to taRightJustify and handle the header Text drawing myself for the desired column.
This code might be helpful for others, so I'll post it anyway:
type
TVirtualTreeColumnsAccess = class(TVirtualTreeColumns);
procedure TForm1.FormCreate(Sender: TObject);
begin
VST.Header.Options := VST.Header.Options + [hoOwnerDraw];
VST.OnHeaderDrawQueryElements := VSTHeaderDrawQueryElements;
VST.OnAdvancedHeaderDraw := VSTAdvancedHeaderDraw;
end;
procedure TForm1.VSTHeaderDrawQueryElements(Sender: TVTHeader; var PaintInfo: THeaderPaintInfo;
var Elements: THeaderPaintElements);
begin
{ Use OwnerDraw only for desired column(s) }
{ other columns drawing will be handled by VST }
if Assigned(PaintInfo.Column) and (PaintInfo.Column.Index = 1) then
Elements := [hpeText];
end;
procedure TForm1.VSTAdvancedHeaderDraw(Sender: TVTHeader;
var PaintInfo: THeaderPaintInfo; const Elements: THeaderPaintElements);
var
DrawFormat: Cardinal;
R: TRect;
begin
{ The event will fire only for the desired column(s) }
if (hpeText in Elements) and Assigned(PaintInfo.Column) then
with PaintInfo do
begin
DrawFormat := DT_LEFT or DT_TOP or DT_NOPREFIX;
if Column.UseRightToLeftReading then
DrawFormat := DrawFormat or DT_RTLREADING;
R := TextRectangle;
R.Left := PaintRectangle.Left + Column.Margin;
TVirtualTreeColumnsAccess(Column.Owner).DrawButtonText(
TargetCanvas.Handle, Column.Text, R,
IsEnabled,
IsHoverIndex and (hoHotTrack in Sender.Options)
and not (tsUseThemes in Sender.Treeview.TreeStates),
DrawFormat);
end;
end;