Accept Drop in an embedde form - delphi

Question

I can setup a drag and drop simple example as outlined in the following code
(excerpted from http://www.chami.com/tips/delphi/111196D.html)
But if I use an embedded form (a form contained in another form I am unable to drop a file on an embedded form: the embedded form does not act as a drop target
unit dropfile;
interface
uses
Windows, Messages, SysUtils, Classes,
Graphics, Controls, Forms, Dialogs;
type
TForm1 = class(TForm)
procedure FormCreate(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
//>>>
// declare our DROPFILES message handler
procedure AcceptFiles( var msg : TMessage );
message WM_DROPFILES;
//<<<
end;
var
Form1: TForm1;
implementation
uses
//>>>
//
// this unit contains certain
// functions that we'll be using
//
ShellAPI;
//<<<
{$R *.DFM}
//>>>
procedure TForm1.AcceptFiles( var msg : TMessage );
const
cnMaxFileNameLen = 255;
var
i,
nCount : integer;
acFileName : array [0..cnMaxFileNameLen] of char;
begin
// find out how many files we're accepting
nCount := DragQueryFile( msg.WParam,
$FFFFFFFF,
acFileName,
cnMaxFileNameLen );
// query Windows one at a time for the file name
for i := 0 to nCount-1 do
begin
DragQueryFile( msg.WParam, i,
acFileName, cnMaxFileNameLen );
// do your thing with the acFileName
MessageBox( Handle, acFileName, '', MB_OK );
end;
// let Windows know that you're done
DragFinish( msg.WParam );
end;
//<<<
procedure TForm1.FormCreate(Sender: TObject);
begin
//>>>
//
// tell Windows that you're
// accepting drag and drop files
//
DragAcceptFiles( Handle, True );
//<<<
end;
end.

Answer 1

You are calling DragAcceptFiles() in the Form's OnCreate event. That event is called only one time during a Form's lifetime. But the Form's window may be recreated multiple times during the Form's lifetime. And that is certainly the case when embedding a Form inside another window. The Form's window gets recreated, but you are not calling DragAcceptFiles() on the newly recreated Form window. That is why your WM_DROPFILES message handler stops working.
To account for window recreation, you need to override the Form's virtual CreateWnd() and call DragAcceptFiles() from there instead.
unit dropfile;
interface
uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs;
type
TForm1 = class(TForm)
private
protected
procedure CreateWnd; override;
procedure DestroyWnd; override;
public
// declare our DROPFILES message handler
procedure AcceptFiles(var msg: TMessage); message WM_DROPFILES;
end;
var
Form1: TForm1;
implementation
uses
ShellAPI;
{$R *.DFM}
procedure TForm1.AcceptFiles(var msg: TMessage);
var
i, nCount: Integer;
acFileName: array [0..MAX_PATH-1] of Char;
begin
// find out how many files we're accepting
nCount := DragQueryFile(msg.WParam, $FFFFFFFF, nil, 0);
// query Windows one at a time for the file name
for i := 0 to nCount-1 do
begin
DragQueryFile(msg.WParam, i, acFileName, MAX_PATH);
// do your thing with the acFileName
MessageBox(Handle, acFileName, '', MB_OK);
end;
// let Windows know that you're done
DragFinish(msg.WParam);
end;
procedure TForm1.CreateWnd;
begin
inherited;
// tell Windows that you're
// accepting drag and drop files
DragAcceptFiles(Handle, True);
end;
procedure TForm1.DestroyWnd;
begin
// tell Windows that you're no
// longer accepting drag and drop files
DragAcceptFiles(Handle, False);
inherited;
end;
end.