How to match several patterns, but each only once - grep

Question

I know that if I have a file of patterns I can use
grep -f pat_file search_file
to search the file normally. How would you approach performing this task so that the command looks for each pattern only once?
I'm looking for efficiency, so it might be that simply writing a python program is the most efficient way to do it, but I bet there's something out there.

Answer 1

I would do this in awk:
FNR == NR { pattern[NR] = $0; next }
{
for (i in pattern) {
if ($0 ~ pattern[i]) {
print
delete pattern[i]
continue
}
}
}
To be called as follows:
awk -f script.awk patterns infile
where patterns contains your patterns and infile is the file you want to search.
The first command reads the patterns into an array; the second command (only executed for files after the first file) loops over the patterns, prints matching lines, deletes the pattern from the array and skips the rest of the patterns.
For an example input of
line with pattern1
another line with pattern1
line with pattern2
pattern1 again
pattern3 now
and pattern2
and a pattern file
pattern1
pattern2
pattern3
the output is
$ awk -f script.awk patterns infile
line with pattern1
line with pattern2
pattern3 now
To optimize, you could add a check after the delete statement to see if there are any patterns left and exit if not.

Answer 2

This MAY be what you're looking for:
awk '
NR==FNR { regexps[$0]; next }
{
found = 0
for (regexp in regexps) {
if ($0 ~ regexp) {
found = 1
delete regexps[regexp]
}
}
}
found
' pat_file search_file
but since you haven't provided any testable sample input and expected output it's just an untested guess.
By the way - never use the word "pattern" to describe what type of matching you want as it's ambiguous, use "string" or "regexp", whichever you really mean.