Query not working in neo4j - neo4j

Question

USING PERIODIC COMMIT
LOAD CSV WITH HEADERS FROM "file:///dept_emp.csv" AS row
MATCH (emp_no:Employee {emp_no: row.emp_no})
MATCH (dept_no:departments {dept_no: row.dept_no})
MERGE(Employee)-[:belongs_to{from_date: row.from_date,to_date:
row.to_date}]->(departments);
i want to make a relationship with properties using this query the structure of node
employee is
[
gender M
emp_no 10001
birth_date 1953-09-02
last_name Facello
hire_date 1986-06-26
first_name Georgi
]
node departements is
[
dept_no d009
dept_name Customer Service
]
structure of file
dept_emp.csv is
(
emp_no dept_name from_date to_date
)
the ide does'nt showing an error just start processing and after 6 hour still processing.

Answer 1

I think you may be a bit confused about match syntax, for which part is the variable, and which is the node label.
MATCH (emp_no:Employee {emp_no: row.emp_no})
In the above match, :Employee is the label of the node. emp_no is the variable bound to the :Employee node that is matched.
Later in the query, you have this:
MERGE(Employee)-[:belongs_to{from_date: row.from_date,to_date:
row.to_date}]->(departments);
The problem here is that Employee and departments don't refer to anything you've matched to previously, this is the first occurrence of these variables, and that will throw off what this MERGE is doing. As it is, it is checking all relationships between all nodes (and doing this for every row in your CSV), looking for :belongs_to relationships with the given date properties.
I suggest you stop the query (by killing Neo4j if necessary) cleaning up the data (in case it needs it) and trying again, but try a MERGE with the variables you previously bound:
MERGE(emp_no)-[:belongs_to{from_date: row.from_date,to_date:
row.to_date}]->(dept_no);
Make sure you have indexes or unique constraints on :Employee(emp_no) and :departments(dept_no) for fast matching.