tcl data formats confusion - foreach

Question

The motivation behind this question is learning...
I have done some TCL programming and I do have a working code, but I do not understand why some syntax is working and another not.
Problem description:
I'm writing a code that needs to set the voltages for power and ground nets.
After I enter the VDD nets as a string,
set POWER_NETS "vdd=1.1 vdda=1.2 vref=1.1"
then a simple TCL code should construct and execute the following commands:
set_vdd vdd 1.1
set_vdd vdda 1.2
set_vdd vref 1.1
That is all. It seems trivial, but I have had some difficulty implementing it. I still do not understand why sometimes my code does not work, although it seems correct to me.
Working solution: The only working solution that I came up with is following:
foreach ITEM [split $POWER_NETS] {
set NET [lindex [split $ITEM =] 0]
set VOLTAGE [lindex [split $ITEM =] 1]
set_vdd $NET $VOLTAGE
}
That's a lot of code for such a simple operation. When written in a more condensed form it still works:
foreach ITEM [split $POWER_NETS] {
set_vdd [lindex [split $ITEM =] 0] [lindex [split $ITEM =] 1]
}
But I still have a feeling that there is room for improvement here.
Learning objective: I would like to settle with this solution as optimal code (it is both short and comprehensive)
foreach ITEM [split $POWER_NETS] {
set_vdd [split $ITEM =]
}
Unfortunately this does not work. The tool that interprets the set_vdd command complains that
no value given for parameter "voltage" (use -help for full usage) :
I do not understand why this does not work. What is the difference?
When I replace set_vdd with puts, it does print all the values. So all information is there. Isn't it?
nlv12345#acc3081 CHAR_OUT_LOGS $ tclsh
% set POWER_NETS "vdd=1.1 vdda=1.2 vref=1.1"
vdd=1.1 vdda=1.2 vref=1.1
% foreach ITEM [split $POWER_NETS] {
puts [split $ITEM =]
}
vdd 1.1
vdda 1.2
vref 1.1
%

Answer 1

The error message is less than optimal, but the problem is that you're passing the two words out of split as a single argument to set_vdd.
If your Tcl interpreter is any currently-supported version, you can instead do this:
foreach ITEM [split $POWER_NETS] {
set_vdd {*}[split $ITEM =]
}
The {*} is a marker to say “take this list — the rest of this word — and split it into separate arguments”. While it's formally not an operator but rather a syntactic part of the Tcl language, calling it the “expansion operator” won't confuse you a lot.
Older, unsupported versions of Tcl (8.4 and before) require the use of eval to do this. You're probably OK with:
foreach ITEM [split $POWER_NETS] {
eval set_vdd [split $ITEM =]
}
but really it would be safer to do this:
foreach ITEM [split $POWER_NETS] {
eval [linsert [split $ITEM =] 0 set_vdd]
}
As you can see, the {*} simplifies things quite a bit.
However, I'd actually do this:
foreach {ITEM KEY VALUE} [regexp -all -inline {(\w+)=([\d.]+)} $POWER_NETS] {
set_vdd $KEY $VALUE
}
Like that, unexpected things in the POWER_NETS value won't cause so much trouble. OTOH, if you're not used to regular expressions then perhaps now is not the time to start with regexp…

Answer 2

Two other simple solutions, for inspiration and further learning:
set POWER_NETS "vdd=1.1 vdda=1.2 vref=1.1"
foreach ITEM [split $POWER_NETS] {
lassign [split $ITEM =] NET VOLTAGE
set_vdd $NET $VOLTAGE
}
This one uses lassign to assign the parts of ITEM instead of splitting them into nameless parameters.
set POWER_NETS [string map {= { }} "vdd=1.1 vdda=1.2 vref=1.1"]
foreach {NET VOLTAGE} [split $POWER_NETS] {
set_vdd $NET $VOLTAGE
}
This one replaces the equals signs with spaces and then lets foreach extract the two values pairwise.
Documentation:
foreach,
lassign,
set,
split,
string