How to avoid crash with Thread.terminate command? - delphi

Question

Scenario 1) When I click button1 and then close form with X while thread is working I get "Thread Error: The handle is invalid"
Scenario 2) When I close application without clicking button1 I get "Access Violation ..."
procedure TForm1.Button1Click(Sender: TObject);
begin
ProccesSupervisor:= TMyThread0.Create(True);
ProccesSupervisor.FreeOnTerminate:=true;
ProccesSupervisor.Priority := tpNormal;
ProccesSupervisor.Resume;
end;
procedure TMyThread0.Execute;
begin
repeat
//some code here
until ProccesSupervisor.terminated=true;
end;
procedure TForm1.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
begin
ProccesSupervisor.Terminate;
ProccesSupervisor.WaitFor;
end;

Answer 1

Never reference a thread object when FreeOnTerminate = true. The thread may already have finished its work and destroyed itself, so accessing it may not be safe.
In your OnCloseQuery event handler, you furthermore are accessing an uninitialized object if Button1 has not been clicked.
If you want to control the lifetime of the thread, leave FreeOnTerminate = false.
In your OnCloseQuery event handler, check if the thread is assigned before terminating it, and also prevent a Button1 click event to start more than one thread at a time.
In TMyThread0.Execute(), there must not be a reference to a specific thread instance when accessing the fields and methods of the class. Write this instead:
until Terminated;

Answer 2

Do not use TThread.WaitFor() with TThread.FreeOnTerminate=True.
When Execute() exits, if TThread.FreeOnTerminate=True then the TThread object destroys itself, closing the thread handle that TThread.WaitFor() waits on. So you may see the "invalid handle" error. Or you may get an access violation instead, or any number of other unexpected errors/symptoms, since you have undefined behavior due to a race condition where WaitFor() might be called on an invalid object, or usually the object is destroyed while WaitFor() is still running. And WaitFor() raises an exception on any OS error, including the "invalid handle" error.
Setting TThread.FreeOnTerminate=True is primarily meant to be used with threads that are forgotten about once they are started. If you need to reference a thread after it is started, do not use FreeOnTerminate at all. You don't want the thread to disappear behind your back.
Also, Execute() should not be accessing its Terminated property via an external object pointer. Use the Self pointer instead.
Try this instead:
procedure TForm1.Button1Click(Sender: TObject);
begin
ProccesSupervisor := TMyThread0.Create(False);
end;
procedure TForm1.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
begin
if ProccesSupervisor <> nil then
begin
ProccesSupervisor.Terminate;
ProccesSupervisor.WaitFor;
FreeAndnil(ProccesSupervisor);
end;
end;
procedure TMyThread0.Execute;
begin
while not Terminated do
begin
//some code here
end;
end;
If you absolutely must set TThread.FreeOnTerminate=True, then you should use the TThread.OnTerminate event to know when the thread disappears, but still stay away from TThread.WaitFor(), do your own error handling, eg:
procedure TForm1.Button1Click(Sender: TObject);
begin
ProccesSupervisor := TMyThread0.Create(True);
ProccesSupervisor.FreeOnTerminate := True;
ProccesSupervisor.OnTerminate := ThreadTerminated;
ProccesSupervisor.Resume;
end;
procedure TForm1.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
var
H: array[0..1] of THandle;
Msg: TMsg;
begin
if ProccesSupervisor <> nil then
begin
ProccesSupervisor.Terminate;
//ProccesSupervisor.WaitFor;
H[0] := ProccesSupervisor.Handle;
H[1] := Classes.SyncEvent;
WaitResult := 0;
repeat
case MsgWaitForMultipleObjects(2, H, False, INFINITE, QS_SENDMESSAGE) of
WAIT_OBJECT_0, WAIT_FAILED: Break;
WAIT_OBJECT_0 + 1: CheckSynchronize;
WAIT_OBJECT_0 + 2: PeekMessage(Msg, 0, 0, 0, PM_NOREMOVE);
end;
until ProccesSupervisor = nil;
end;
end;
procedure TForm1.ThreadTerminated(Sender: TObject);
begin
ProccesSupervisor := nil;
end;
procedure TMyThread0.Execute;
begin
while not Terminated do
begin
//some code here
end;
end;