Trimming String request parameters in controllers actions - grails

Question

I am working in a grails 2.4.4 application which has some legacy code that doesn't use binding or command objects in controllers, in this application the request parameters are passed from controller actions directly to java classes using their constructors.
We want to trim white spaces from strings parameters (just like Grails does by default when binding) but without using binding or command objects.
Maybe injecting a cloned version of the params varible but with trimmed values?
Have any of you done something like this?

Answer 1

Here's an implementation I used in a 2.x app in a filter. It supports nested objects by calling the method recursively:
def filters = {
blankToNullAndTrim(controller: '*', action: '*') {
before = {
convertBlanksToNullsAndTrim params
true
}
}
}
private static void convertBlanksToNullsAndTrim(Map<String, Object> map) {
def keys = map.keySet() as List // copy to avoid ConcurrentModificationException
for (name in keys) {
def value = map[name]
if (value instanceof String) {
value = value.trim()
if (value.length() == 0) {
map[name] = null // have to explicity set to null, not remove
}
else {
map[name] = value // update if trimmed
}
}
else if (value instanceof Map) {
// empty nested param, e.g. "location":["id":""]
convertBlanksToNullsAndTrim value
}
}
}
and here's the equivalent implementation (with type information included so you can use #GrailsCompileStatic) for use in an interceptor when you upgrade to Grails 3.x:
boolean before() {
convertBlanksToNullsAndTrim params
true
}
private void convertBlanksToNullsAndTrim(Map<String, Object> map) {
List<String> keys = map.keySet() as List // copy to avoid ConcurrentModificationException
for (String name in keys) {
def value = map[name]
if (value instanceof String) {
value = value.trim()
if (value.length() == 0) {
map[name] = null // have to explicity set to null, not remove
}
else {
map[name] = value // update if trimmed
}
}
else if (value instanceof Map) {
// empty nested param, e.g. "location":["id":""]
convertBlanksToNullsAndTrim value
}
}
}

Answer 2

One option will be to use Dynamically Resolved Variables in UrlMappings.groovy. For example if there is a mapping as follows:
"/airport/status(controller: 'airport', action: 'checkStatus')
and expecting a request parameter as airportName then it can be rewritten as:
"/airport/status(controller: 'airport', action: 'checkStatus') {
airportName = { params.airportName?.trim() }
}
This would make sure that the arbitrary variable is set to params after trimming the actual request parameter airportName. Care has to be taken to use the same variable name as the request parameter to support the legacy system underneath.
Another option can be to use a filter across the controller to trim the request parameters. Something like:
class UtilityFilters {
def filters = {
trim(controller: "airport", action: "*") {
before = {
// If immutable then make a copy and edit
params.airportName = params.airportName?.trim()
return true
}
}
}
}