Service Application in Delphi do not Open an Exe file on desktop? - delphi

Question

I am using a Service Application in Delphi. This is my code in ServiceExecute method
procedure TMDPSERVICE.ServiceExecute(Sender: TService);
const
SecBetweenRuns = 10;
var
Count: Integer;
begin
while not Terminated do // loop around until we should stop
begin
Inc(Count);
if Count >= SecBetweenRuns then
begin
if not DoFindTask('c:\weblod.exe') then
WinExec(PAnsiChar('c:\weblod.exe'), SW_NORMAL);
end;
Sleep(10);
end;
end;
I can see weblod.exe file on taskmanager but it is not showing on Desktop?

Answer 1

Services run in an isolated session, session 0. Interactive desktops are always in different sessions. Read about session 0 isolation to learn more.
If you want to launch the process on an interactive desktop you need something like this: create process in user session from service

Answer 2

First and foremost, you are misusing the TService.OnExecute event. Specifically, you are never calling ServiceThread.ProcessRequests() so your service can respond to SCM requests. At the very least, you must add that to your loop:
procedure TMDPSERVICE.ServiceExecute(Sender: TService);
const
SecBetweenRuns = 10;
var
Count: Integer;
begin
while not Terminated do // loop around until we should stop
begin
Inc(Count);
if Count >= SecBetweenRuns then
begin
if not DoFindTask('c:\weblod.exe') then
WinExec(PAnsiChar('c:\weblod.exe'), SW_NORMAL);
end;
Sleep(10);
ServiceThread.ProcessRequests(False); // <-- add this
end;
end;
A better (and preferred) option is to not use the OnExecute event at all. TService automatically processes SCM requests when no OnExecute handler is assigned. You should use the TService.OnStart event to start a worker thread, and use the TService.OnStop/TService.OnShutdown events to terminate that thread:
type
TMyTaskThread = class(TThread)
protected
procedure Execute; override;
end;
procedure TMyTaskThread.Execute;
const
SecBetweenRuns = 10;
var
Count: Integer;
begin
while not Terminated do // loop around until we should stop
begin
Inc(Count);
if Count >= SecBetweenRuns then
begin
if not DoFindTask('c:\weblod.exe') then
WinExec(PAnsiChar('c:\weblod.exe'), SW_NORMAL);
end;
Sleep(10);
end;
end;
type
TMDPSERVICE = class(TService)
procedure ServiceStart(Sender: TService; var Started: Boolean);
procedure ServiceStop(Sender: TService; var Stopped: Boolean);
procedure ServiceShutdown(Sender: TService);
private
FTask: TMyTaskThread;
end;
procedure TMDPSERVICE.ServiceStart(Sender: TService; var Started: Boolean);
begin
FTask := TMyTaskThread.Create(False);
Started := True;
end;
procedure TMDPSERVICE.ServiceStop(Sender: TService; var Stopped: Boolean);
begin
ServiceShutdown(Sender);
Stopped := True;
end;
procedure TMDPSERVICE.ServiceShutdown(Sender: TService);
begin
if Assigned(FTask) then
begin
FTask.Terminate;
while WaitForSingleObject(FTask.Handle, WaitHint-100) = WAIT_TIMEOUT do
ReportStatus;
FreeAndNil(FTask);
end;
end;
Now, with that said, WinExec() has been deprecated since Windows 95 was first introduced. Don't use WinExec() at all, especially from a service. You need to use CreateProcessAsUser() instead. Not only does that allow you to specify which desktop to run the process on, it also allows you to specify which user session the process runs in. This is especially important in Windows Vista and later due to Session 0 Isolation, because logged-in users do not run in the same session as services anymore (which is also why the TService.Interactive property is no longer supported, either). If you don't specify a user session, the process would run in the same session as the service, and as the same user that the service is running as (which is usually SYSTEM). A logged-in user will never see the process.
Try something more like this:
function WTSGetActiveConsoleSessionId: DWORD; stdcall; external 'Wtsapi32.dll';
function WTSQueryUserToken(SessionId: ULONG; var phToken: THandle): BOOL; stdcall; external 'Wtsapi32.dll';
function CreateEnvironmentBlock(var lpEnvironment: Pointer; hToken: THandle; bInherit: BOOL): BOOL; stdcall; external 'Userenv.dll';
function DestroyEnvironmentBlock(lpEnvironment: Pointer): BOOL; stdcall; external 'Userenv.dll';
function RunTaskOnUserDesktop(CmdLine: string): Boolean;
var
hToken: THandle;
env: Pointer;
si: STARTUPINFO;
pi: PROCESS_INFORMATION;
begin
Result := False;
// WTSGetActiveConsoleSessionId() returns the ID of the user session that is
// logged in to the physical console (keyboard/mouse/screen). If remote users
// can login to your machine, and you want to run your process in a remote
// user's session, use WTSEnumerateSessions() instead to find the ID of the
// desired logged-in user session...
//
if not WTSQueryUserToken(WTSGetActiveConsoleSessionId(), hToken) then
Exit;
try
if not CreateEnvironmentBlock(env, hToken, False) then
Exit;
try
ZeroMemory(#si, SizeOf(si));
si.cb := SizeOf(si);
si.lpDesktop := 'Winsta0\Default';
si.dwFlags := STARTF_USESHOWWINDOW;
si.wShowWindow := SW_SHOWNORMAL;
Result := CreateProcessAsUser(hToken, nil, PChar(CmdLine), nil, nil, False, CREATE_UNICODE_ENVIRONMENT, env, nil, si, pi);
if Result then
begin
CloseHandle(pi.hThread);
CloseHandle(pi.hProcess);
end;
finally
DestroyEnvironmentBlock(env);
end;
finally
CloseHandle(hToken);
end;
end;
...
const
SecBetweenRuns = 10;
var
Count: Integer;
begin
while not Terminated do // loop around until we should stop
begin
Inc(Count);
if Count >= SecBetweenRuns then
begin
if not DoFindTask('c:\weblod.exe') then
RunTaskOnUserDesktop('c:\weblod.exe');
end;
Sleep(10);
end;
end;