Joining image - Delphi - delphi

Question

How do I merge two images with Delphi . I thought of using CopyRect but could not implement it. How do I attach a JPG image with the bitmap rectangle-shaped . I need to center the image within the rectangle , how?
procedure TForm1.Button1Click(Sender: TObject);
var
bmp, bmp1: TBitmap;
jpg: TJpegImage;
scale: Double;
begin
if opendialog1.execute then
begin
jpg := TJpegImage.Create;
try
jpg.Loadfromfile(opendialog1.filename);
if jpg.Height > jpg.Width then
scale := 98 / jpg.Height
else
scale := 98 / jpg.Width;
bmp := TBitmap.Create;
try
{Create thumbnail bitmap, keep pictures aspect ratio}
bmp.Width := Round(jpg.Width * scale);
bmp.Height:= Round(jpg.Height * scale);
//BPM1
bmp1 := TBitmap.Create;
bmp1.SetSize(98, 98);
bmp1.Canvas.Brush.Color := RGB(243,243,243);
bmp1.Canvas.Pen.Style:= psClear;
bmp1.Canvas.Rectangle(0, 0, 98, 98);
bmp.Canvas.StretchDraw(bmp.Canvas.Cliprect, jpg);
{Draw thumbnail as control}
//Juntar os 2
self.Canvas.Draw(10, 10, bmp1);
self.Canvas.Draw(10, 10, bmp);
Logo.Picture.Assign(bmp);
{Convert back to JPEG and save to file}
jpg.Assign(bmp);
jpg.SaveToFile(
ChangeFileext(opendialog1.filename, '_thumb.JPG')
);
finally
bmp.free;
bmp1.free;
end;
finally
jpg.free;
end;
end;
end;

Answer 1

You should not be using bmp.Canvas.ClipRect as the destination rectangle for your StretchDraw() call. Specify the actual rectangle you want, which in this case is the full dimensions of bmp.
If you want a border all the way around the scaled image but keep the 98x98 dimensions of the final image, like your example JPG shows, then your scale needs to be based on a value less than 98px. For instance, to have a border at least 10x wide, reduce your scale by 20px (10px on each side). If you don't reduce your scale, the width and/or height of the scaled image will be exactly 98px, which is not what your example JPG shows.
When you go to draw bmp on top of bmp1, center bmp by subtracting its dimensions from bmp1's dimensions and dividing the result in half.
And do not draw on the Form's Canvas from outside of the Form's OnPaint event. If you want the Form to display an image, use the TImage component for that.
Try something more like this:
procedure TForm1.Button1Click(Sender: TObject);
var
bmp, bmp1: TBitmap;
jpg: TJPEGImage;
scale: Double;
begin
if OpenDialog1.Execute then
begin
jpg := TJPEGImage.Create;
try
jpg.LoadFromFile(OpenDialog1.FileName);
if jpg.Height > jpg.Width then
scale := 78 / jpg.Height
else
scale := 78 / jpg.Width;
bmp := TBitmap.Create;
try
{Create thumbnail bitmap, keep pictures aspect ratio}
bmp.SetSize(Round(jpg.Width * scale), Round(jpg.Height * scale));
bmp.Canvas.StretchDraw(Rect(0, 0, bmp.Width, bmp.Height), jpg);
//BPM1
bmp1 := TBitmap.Create;
try
bmp1.SetSize(98, 98);
bmp1.Canvas.Brush.Color := RGB(243, 243, 243);
bmp1.Canvas.Pen.Style := psClear;
bmp1.Canvas.Rectangle(0, 0, bmp1.Width, bmp1.Height);
bmp1.Canvas.Draw((bmp1.Width - bmp.Width) div 2, (bmp1.Height - bmp.Height) div 2, bmp);
{Draw thumbnail as control}
//Juntar os 2
Image1.Picture.Assign(bmp1);
finally
bmp1.free;
end;
Logo.Picture.Assign(bmp);
{Convert back to JPEG and save to file}
jpg.Assign(bmp);
jpg.SaveToFile(ChangeFileExt(OpenDialog1.FileName, '_thumb.JPG'));
finally
bmp.free;
end;
finally
jpg.free;
end;
end;
end;

Answer 2

I was stirring until I fulfilled what he wanted. The only thing I could not , was to change the image background , I would put in the empty spot RGB ( 0,0,0 ) , did the tests, but failed.
procedure TForm1.Button2Click(Sender: TObject);
var
bmp: TBitmap;
jpg: TJPEGImage;
scale: Double;
widthL, HeightL, pt1, pt2, pt3, pt4: integer;
verdd : boolean;
begin
if OpenDialog1.Execute then
begin
try
jpg := TJPEGImage.Create;
verdd := false;
try
//Dimensões
widthL := 98;
HeightL := 98;
jpg.LoadFromFile(OpenDialog1.FileName);
if (jpg.Height >= jpg.Width) AND (HeightL <= jpg.Height) then begin
scale := widthL / jpg.Height;
end else if (jpg.Height <= jpg.Width) AND (widthL <= jpg.Width) then begin
scale := HeightL / jpg.Width;
end else begin
verdd := true;
end;
bmp := TBitmap.Create;
try
{Create thumbnail bitmap, keep pictures aspect ratio}
bmp.SetSize( widthL,HeightL);
if not verdd then begin
pt1 := (widthL - Round(jpg.Width * scale)) div 2;
pt2 := (HeightL - Round(jpg.Height * scale)) div 2;
pt3 := Round(jpg.Width * scale) + pt1;
pt4 := Round(jpg.Height * scale) + pt2;
bmp.Canvas.StretchDraw(Rect(pt1, pt2, pt3, pt4), jpg);
end else begin
pt1 := (widthL - jpg.Width) div 2;
pt2 := (HeightL - jpg.Height) div 2;
pt3 := jpg.Width + pt1;
pt4 := jpg.Height + pt2;
bmp.Canvas.StretchDraw(Rect(pt1, pt2, pt3, pt4), jpg);
end;
Logo.Picture.Assign(bmp);
{Convert back to JPEG and save to file}
jpg.Assign(bmp);
jpg.SaveToFile(ChangeFileExt(OpenDialog1.FileName, '_thumb.JPG'));
finally
bmp.free;
end;
finally
jpg.free;
end;
except
showMessage('Erro ao carregar imagem'); ///////////////////////////////////
end;
end;
end;