Neo4J - select records with max count - neo4j

Question

I struggle to write a query, that will return info about most played tracks for every user.
I go with something like this:
MATCH (l:Listener)-[lo:LOGS]->(s:Scrobble)-[f:FEATURES]->(t:Track)<-[p:PERFORMS]-(a:Artist)
with l,a,count(*) as numberOfScrobbles
return l.name, a.title, numberOfScrobbles
and get a list of values: User name - Artist name - Number of scrobbled tracks created by given artist.
My goal is to acquire most favorite artist for every user (artist with most scrobbles for each user). The closest i get is with this:
MATCH (l:Listener)-[lo:LOGS]->(s:Scrobble)-[f:FEATURES]->(t:Track)<-[p:PERFORMS]-(a:Artist)
with l,a,count(*) as numberOfScrobbles
return l.name, max(numberOfScrobbles)
which gives me number of tracks played by a favourite artist for given user, but how can I join proper artist's name to this result?
Any clues/tips?

Answer 1

One idea (maybe there's a much simpler solution):
MATCH (l:Listener)-[lo:LOGS]->(s:Scrobble)-[f:FEATURES]->(t:Track)<-[p:PERFORMS]-(a:Artist)
with l,a,count(*) as numberOfScrobbles
with l, collect(a) as artists, collect(numberOfScrobbles) as counts
with l, artists, reduce(x=[0,0], idx in range(0,size(counts)-1) | case when counts[idx] > x[1] then [idx,counts[idx]] else x end)[0] as index
return l.name, artists[index]
The reduce function is used to find the position of the largest element in the array. That index is then used to subscript the artists array.

Answer 2

Here is a query that should improve on #StefanAmbruster's fine answer. It uses the MAX() function to find the max numberOfScrobbles per listener; extracts all the artists that scored that max number for that listener; and then returns each listener, its collection of winning artists, and the max count.
MATCH (l:Listener)-[:LOGS]->(:Scrobble)-[:FEATURES]->(:Track)<-[:PERFORMS]-(a:Artist)
WITH l, a, count(*) as numberOfScrobbles
WITH l, collect(a) as artists, collect(numberOfScrobbles) as counts, MAX(numberOfScrobbles) AS max_nos
WITH l, max_nos, extract(i IN range(0, size(counts)-1) | CASE WHEN counts[i] = max_nos THEN artists[i] ELSE NULL END) AS as
RETURN l.name, as, max_nos;