Nested foreach loops in tcl - foreach

Question

I've tried looking all over the place and haven't found a good answer for this. I'm trying to write nested foreach loops in tcl that read lines from two different text files. The inner foreach loop will run completely through but the outer foreach loop will break after just evaluating the first line in the file. The text files look something like this (except much larger).
input1.txt:
1
2
3
4
5
6
7
8
9
10
input2.txt:
a
b
c
d
e
f
g
h
i
j
and my nested foreach loops are constructed like this:
# Open file 1;
set FID1 [open input1.txt r];
# Open file 2
set FID2 [open input2.txt r];
# Open an output file to check the foreach loops;
set outFID [open outputcheck.txt w];
# Nest the foreach loops to read both files
foreach PropLine [split [read $FID1] \n] {
foreach GMprop [split [read $FID2] \n] {
puts $outFID "$PropLine $GMprop";
}
}
close $FID1;
close $FID2;
close $outFID;
and my outputcheck.txt file contains
1 a
1 b
1 c
1 d
1 e
1 f
1 g
1 h
1 i
1 j
I am running this code through the OpenSEES.exe executable on a PC with Windows 7 operating system.
Thanks in advance for any insight.

Answer 1

If you want to do something with file2 for every line of file1, then
foreach PropLine [split [read $FID1] \n] {
foreach GMprop [split [read $FID2] \n] {
puts $outFID "$PropLine $GMprop";
}
# jump back to the start of the file, so you can re-read it
# for the next iteration of the outer foreach loop
seek $FID2 0 start
}
But, it just looks like you want to pair the lines, so
foreach PropLine [split [read -nonewline $FID1] \n] \
GMprop [split [read -nonewline $FID2] \n] \
{
puts $outFID "$PropLine $GMprop";
}
Tcl lets you iterate over multiple lists simultaneously, very handy: http://tcl.tk/man/tcl8.6/TclCmd/foreach.htm
Although I'd be tempted to read the files line-by-line:
while {true} {
set status1 [gets $FID1 PropLine]
set status2 [gets $FID2 GMprop]
if {$status1 == -1 && $status2 == -1} break
puts $outFID "$PropLine $GMprop"
}