Show multiple Columns contents in a ComboBox - delphi

Question

I want to show FirstName and LastName in a Combobox drop down.
The Problem is That I should work On 2 fields existing in a Table.
I checked the TDBlLookUpComboBox but the ListFields properties doesn't work for me in Delphi Xe.
I set The properties of TDBlLookUpComboBox to
DataSource :my datasource
ListFields : SUR_NAME; FIRST_NAME
Now, I am doing it by a basic way :
nameClient := Concat( sqlqry1.Fields.FieldByName('FIRST_NAME').AsString,' ',
sqlqry1.Fields.FieldByName('SUR_NAME').AsString);
cbbClient.Items.Add(nameClient);

Answer 1

Change the input
Just change the source data going into the DBCombo by putting in a query:
select concat(SUR_NAME,' ',FIRST_NAME) as NAME, * from mytable;
Now you can display the data in your combo box.
Make the output look nice in the combobox
Obviously you'll be using a TDBILookUpComboBox but everything else is the same.
In order to make multiple columns in the drop down you'll have to do your own drawing.
This can be done by changing the style to csOwnerDrawFixed and assigning the OnDrawItem event.
See the sample code below:
unit Unit18;
interface
uses
Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;
type
TForm18 = class(TForm)
ComboBox1: TComboBox;
procedure ComboBox1DrawItem(Control: TWinControl; Index: Integer; Rect: TRect; State: TOwnerDrawState);
private
public
end;
var
Form18: TForm18;
implementation
uses
System.Types,
StrUtils;
{$R *.dfm}
procedure TForm18.ComboBox1DrawItem(Control: TWinControl; Index: Integer; Rect: TRect; State: TOwnerDrawState);
var
Columns: TStringDynArray;
ColCount: Integer;
ItemText: string;
DC: HDC;
DrawRect: TRect;
Middle: integer;
begin
ItemText:= ComboBox1.Items[index];
Columns:= SplitString(ItemText, '|');
ColCount:= Length(Columns);
// For Demo purposes only the first 2 columns are displayed.
DC:= ComboBox1.Canvas.Handle;
Combobox1.Canvas.FillRect(Rect);
Middle:= Rect.Left + Rect.Width div 2;
Combobox1.Canvas.MoveTo(Middle, Rect.Top);
Combobox1.Canvas.LineTo(Middle, Rect.Bottom);
if ColCount > 0 then begin
DrawRect:= Rect;
OffsetRect(DrawRect,1,0);
DrawRect.Right:= DrawRect.Right - DrawRect.Width div 2;
DrawText(DC, Columns[0], Length(Columns[0]), DrawRect, 0);
end;
if ColCount > 1 then begin
DrawRect:= Rect;
OffsetRect(DrawRect,1,0);
DrawRect.Left:= DrawRect.Left + DrawRect.Width div 2;
DrawText(DC, Columns[1], Length(Columns[1]), DrawRect, 0);
end;
end;
end.
Put the following text in the Items:
test | test
line2 | part2
line 4 | part3
line 6
And this is what will be displayed: