memory overflow using the object list with generics - delphi

Question

Step 1:
write an application with the code:
unit Unit1;
interface
uses
System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants, System.Generics.Collections,
FMX.Types, FMX.Graphics, FMX.Controls, FMX.Forms, FMX.Dialogs, FMX.StdCtrls;
type
TObjChild = class;
TObjTest = class
private
FName: string;
FChilds: TList<TObjChild>;
public
property Name: string read FName write FName;
property Childs: TList<TObjChild> read FChilds write FChilds;
constructor Create;
destructor Destroy; override;
end;
TObjChild = class
private
FAdress: string;
FPostalCode: string;
public
property Adress: string read FAdress write FAdress;
property PostalCode: string read FPostalCode write FPostalCode;
end;
TForm1 = class(TForm)
Button1: TButton;
procedure Button1Click(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
end;
var
Form1: TForm1;
implementation
{$R *.fmx}
{ TObjTeste }
constructor TObjTest.Create;
begin
FChilds := TObjectList<TObjChild>.Create;
end;
destructor TObjTest.Destroy;
var
i: integer;
begin
for i := 0 to FChilds.count -1 do
begin
FChilds[I].Free;
end;
FreeAndNil(FChilds);
inherited;
end;
procedure TForm1.Button1Click(Sender: TObject);
var
I: Integer;
ListObjs: TList<TObjTest>;
lObjTeste: TObjTest;
lObjChild: TObjChild;
J: Integer;
begin
ListObjs := TList<TObjTest>.Create;
for I := 0 to 5000 do
begin
lObjTeste := TObjTest.Create;
for J := 0 to 2000 do
begin
lObjChild := TObjChild.Create;
lObjTeste.FChilds.Add(lObjChild)
end;
ListObjs.Add(lObjTeste);
end;
if MessageDlg('Delete objects?', TMsgDlgType.mtConfirmation, [TMsgDlgBtn.mbOK], 0) = idOK then
begin
for I := 0 To ListObjs.Count - 1
begin
ListObjs[I].Free;
end;
FreeAndNil(ListObjs);
end;
end;
end.
Step 2: Run application and press button1
After pressing the OK button messagedlg of the application does not release the memory
Step 3: Repeat steps sometimes the application returns a memory low

Answer 1

The problem is here:
constructor TObjTest.Create;
begin
FChilds := TObjectList<TObjChild>.Create;
end;
destructor TObjTest.Destroy;
var
i: integer;
begin
for i := 0 to FChilds.count - 1 do
begin
FChilds[i].Free;
end;
FreeAndNil(FChilds);
inherited;
end;
By default TObjectList<T> takes ownership of its members. So you do not need to, and indeed should not, free the members in the destructor.
So here:
for i := 0 to FChilds.count - 1 do
begin
FChilds[i].Free;
end;
you free the members. But then here:
FreeAndNil(FChilds);
The object list also frees the members. Who have already been freed. That double free leads to your runtime errors.
The fix is to remove the explicit freeing of the object list members and rely on the list to do the work:
destructor TObjTest.Destroy;
begin
FChilds.Free;
inherited;
end;
This ownership of its members is the single reason for the existence of TObjectList<T>. That is the only functionality that it offers beyond that provided by TList<T>. Read about it here: http://docwiki.embarcadero.com/Libraries/en/System.Generics.Collections.TObjectList
Finally, the plural of child is children.