Using TASK Results in code section - task

Question

Based in the users selection on the TASK Wizard page, I need to be able to use the answer to create 5-different variables/variant to use in the FILES & ICONS sections.
Examples;
1.- Results would indicate what directory to place files into.
2.- Results would also indicate what the TEXT in the Perameters would be.
Each example above would be a different variable/variant
These variants would essentially replace #define(s) variable that I am currently using.
My application is a multi-state application with each state having different support file contents, I wish to be able to use the TASK option instead of having a separate exe file for each.

Answer 1

Your question is too broad to cover, so I'll try to show you just a principle of getting [Files] entry DestDir parameter from script code, which is what you can apply also for [Icons] parameters. The key is to use the {code:...} constant in which you can specify a getter function declared in the [Code] section of your script. The following example shows, how to install file into 4 different directories based on selected tasks:
#define PathNone "None"
#define PathBoth "Both"
#define PathFirst "First"
#define PathSecond "Second"
[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program
[Tasks]
Name: TaskFirst; Description: "First task"
Name: TaskSecond; Description: "Second task"
[Files]
Source: "MyApp.exe"; DestDir: "{code:GetMyAppDir}"
[Code]
function GetMyAppDir(Param: string): string;
begin
// check if both tasks are selected; if yes, then assign a subfolder path defined
// by the PathBoth preprocessor variable to the Result
if IsTaskSelected('TaskFirst') and IsTaskSelected('TaskSecond') then
Result := '{#PathBoth}'
else
// both tasks are not selected, so let's check if the first one is; if yes, then
// assign the PathFirst preprocessor variable to the Result
if IsTaskSelected('TaskFirst') then
Result := '{#PathFirst}'
else
// first task nor both are selected, so let's check if the second one is; if so,
// assign the PathSecond preprocessor variable to the Result
if IsTaskSelected('TaskSecond') then
Result := '{#PathSecond}'
else
// no task is selected (this is the last possible situation), let's assign the
// PathNone preprocessor variable to the Result
Result := '{#PathNone}';
// finally prepend to the Result the {app} constant and expand all the constants
Result := ExpandConstant('{app}\' + Result);
end;
Similar you can do with many section parameters, but not all (this is quite a broad topic). Beware also, that some of the parameters are evaluated eariler (when the tasks were not yet seen by the user), some of them later. Also some of the parameters are evaluated more than once (assigned getter functions may execute more than once).
So it depends which parameters are you going to specify that way. For your mentioned [Files] section DestDir parameter and [Icons] section Parameters parameter you are fine with this approach.