Indy SMTP server - how to detect CC & BCC recipients? - delphi

Question

I am trying to develop an SMTP relay server using the Delphi help, Indy examples and Google.
I am just beginning and have a dummy SMTP client which sends a test message to an SMTP server which will later process it and forward it using an SMTP relay.
At the server, I receive one OnRcpt for each recipient (I test with one To, one CC and one Bcc).
I also see the To and CC recipients in AMsg when I handle OnMsgReceive and convert AMsg to a TStringStream (suitably prefixed with To: and CC:), but I don't see the BCC there.
Question: how do I tell which addresses were To, CC and BCC?
Here's some exceedingly simple code. I am setting breakpoints & examining received parameters to try to see what is happing
procedure TEmailMonitorMainForm.IdSMTPServerMsgReceive(ASender: TIdSMTPServerContext;
AMsg: TStream; var VAction: TIdDataReply);
var
LMsg : TIdMessage;
begin
LMsg := TIdMessage.Create(Nil);
LMsg.LoadFromStream(AMsg);
LMsg.Free(); // breakpoint here examine Lmsg
end; // IdSMTPServerMsgReceive()
[Update] when I send, then <message>.BCCList.Count = 1, but when I Receive, it is 0, whereas the received CClist.Count is 1, as it should be.

Answer 1

At the server, I receive one OnRcpt for each recipient (I test with one To, one CC and one Bcc).
The SMTP protocol does not distinguish between To, CC, and BCC recipients. That is an artifact of the email format via its To: and Cc: headers (there is no Bcc: header, though TIdMessage.SaveToFile() creates one so TIdMessage.LoadFromFile() can re-load it). When an SMTP client sends an email to an SMTP server, the client determines the intended recipients and specifies each one in a separate RCPT TO command to the server (that is what allows BCC to work - there is no Bcc: header in the email itself, but the server is given a RCPT TO command for each Bcc recipient). The RCPT TO addresses are the values specified in the TIdSMTPServer.OnRcptTo event, and are collected in the TIdSMTPServerContext.RCPTList property. These addresses are explicitly requested by the SMTP client, and are the only addresses you should deliver the email to (not the recipients specified in the email headers).
I also see the To and CC recipients in AMsg when I handle OnMsgReceive and convert AMsg to a TStringStream (suitably prefixed with To: and CC:), but I don't see the BCC there.
The actual email itself is just arbitrary data as far as an SMTP server is concerned. It is meant to be delivered as-is to each requested recipient. That is why the email data is provided as a TStream in the TIdSMTPServer.OnMsgReceive event, and why TIdSMTPServer in Indy 10 does not provide TIdMessage-based events like it did in Indy 9 and earlier.
If the email is in an RFC 822/2822/5322 format (which it usually is), it will have To: and Cc: headers. When receiving/loading such an email into a TIdMessage, those headers are used to fill in the TIdMessage.Recipients and TIdMessage.CCList properties, respectively. But since there is usually no Bcc: header (unless the email is being loaded from a file created by TIdMessage.SaveToFile()), the TIdMessage.BCCList will not be filled in.
how do I tell which addresses were To, CC and BCC?
Since the SMTP protocol itself does not distinguish between the different recipient types, the only way for you to distinguish between them is to parse the email, looking at its To: and Cc: headers. Any address in the TIdSMTPServerContext.RCPTList property that is not in one of those two headers must be a Bcc recipient. However, there is no guarantee that the other addresses in the TIdSMTPServerContext.RCPTList property will always match the To: and Cc: headers (though they usually will), since technically an SMTP client can send whatever raw data it wants and the SMTP will deliver it as-is without caring what it actually contains.
Here's some exceedingly simple code.
DO NOT use TIdMessage.LoadFromStream() to parse the TStream object provided by the TIdSMTPServer.OnMsgReceive event! It will not always work correctly. The technical reason has been discussed in detail multiple times in the Embarcadero and AToZed forums, for example in this discussion. You need to use the following workaround for the time being. The issue will be addressed in Indy 11:
procedure TEmailMonitorMainForm.IdSMTPServerMsgReceive(ASender: TIdSMTPServerContext; AMsg: TStream; var VAction: TIdDataReply);
var
LMsg : TIdMessage;
LClient: TIdMessageClient;
LIO: TIdIOHandlerStreamMsg;
begin
LMsg := TIdMessage.Create(Nil);
try
//LMsg.LoadFromStream(AMsg);
LClient := TIdMessageClient.Create;
try
LIO := TIdIOHandlerStreamMsg.Create(LClient, AMsg);
LIO.FreeStreams := False;
LIO.EscapeLines := True;
LIO.Open;
LClient.IOHandler := LIO;
LClient.ProcessMessage(LMsg, False);
finally
LClient.Free;
end;
// now you can use LMsg as needed...
finally
LMsg.Free;
end;
end;