Delphy Indy10 - TIdUDPClient - Get the IP I receive packet on - delphi

Question

I have a TIdUDPClient created like this:
myUDPClient := TIdUDPClient.Create(nil);
myUDPClient.ReceiveTimeout := 500;
myUDPClient.Binding.Port := 300;
myUDPClient.Active := True;
The binding IP is not specified because I have 3 ethernet adapters with dynamic addressing (192.168.x.x, 10.10.x.x and 172.16.x.x), so the binding IP is generated by Indy and it is 0.0.0.0.
When I receive a packet I can determine the sender IP, but I cannot determine the local IP on which I received the packet (not 0.0.0.0, but one of the 3 IPs assigned to my computer).
Do you know any method to accomplish this?

Answer 1

Do not assign to Binding.Port directly, assign to myUDPClient.BoundPort instead and let TIdUDPClient assign to Binding.Port internally.
Since you are binding to 0.0.0.0 locally, there is no way to determine the destination IP when using TIdUDPClient to read the packet, since it uses the socket API recvfrom() function, hich does not report that info. The socket API getsockname() function will report 0.0.0.0 because that is what the socket is really bound to.
On Windows XP+, you can use GStack.ReceiveMsg() instead to receive packets. It has a TIdPacketInfo output parameter, which contains has a DestIP field (you have to use Binding.SetSockOpt() to enable ReceiveMsg() to collect that info), eg:
...
myUDPClient.Active := True;
myUDPClient.Binding.SetSockOpt(IPPROTO_IP, IP_PKTINFO, 1);
var
Buffer: TIdBytes;
BufLen: LongWord;
PktInfo: TIdPacketInfo;
begin
SetLength(Buffer, ...);
BufLen := GStack.ReceiveMsg(myUDPClient.Binding.Handle, Buffer, PktInfo);
// use Buffer up to BufLen bytes
// PktInfo.DestIP will be the IP that received the packet
end;
Alternatively, you can switch to TIdUDPServer instead, and create a separate entry in its Bindings collection for each local IP you want to receive packets on:
myUDPServer := TIdUDPServer.Create(nil);
myUDPServer.DefaultPort := 300;
myUDPServer.OnUDPRead := UDPRead;
LocalIPs := TStringList.Create;
try
GStack.AddLocalAddressesToList(LocalIPs);
for I := 0 to LocalIPs.Count-1 do
myUDPServer.Bindings.Add.IP := LocalIPs[I];
finally
LocalIPs.Free;
end;
{
Or this, if you are using an up-to-date Indy 10 snapshot:
LocalIPs := TIdStackLocalAddressList.Create;
try
GStack.GetLocalAddressList(LocalIPs);
for I := 0 to LocalIPs.Count-1 do
myUDPServer.Bindings.Add.SetBinding(LocalIPs[I].IPAddress, myUDPServer.DefaultPort, LocalIPs[I].IPVersion);
finally
LocalIPs.Free;
end;
}
myUDPServer.Active := True;
procedure TMyClass.DoUDPRead(AThread: TIdUDPListenerThread; const AData: TIdBytes; ABinding: TIdSocketHandle);
begin
// ABinding.IP is the local IP address that received this packet...
end;