Creating a DB aware component - TFieldDataLink.Edit causes fields to reload - delphi

Question

I am trying to create a data aware control. I have a TFieldDataLink object with a DataSource and Field hooked up. Everything seemed to be going OK until I tried to edit the value.
I am using the OnDataChange and OnUpdateData events for the TFieldDataLink. It looks like I need to call TFieldDataLink.Edit if I want the OnUpdateData event to be called before moving to a new record or posting. In the sample code below am trying to call .Edit in the OnExit field of the control if changes were made. In my actual app the control consists of several DevExpress lookup combo boxes and I am trying to call .Edit in OnEditValueChanged.
My problem is the call to TFieldDataLink.Edit causes the OnDataChange event to fire again. That forces a reload of my edit with the original value. If I make a second change after the Dataset is already in edit mode then a OnDataChange event is not fired.
Here is a test unit I that has everything on one form. In my actual app this is split out into a more complicated component.
When should I be calling .Edit without getting OnUpdateData to change? I know I could set a member variable to stop the reload or unhook the events before calling .Edit. It feels like there is something I don't understand about the TFieldDataLink object and I should not need to resort to those tricks.
unit Unit1;
interface
uses
Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
Vcl.Controls, Vcl.Forms, Vcl.Dialogs, uADStanIntf, uADStanOption, uADStanParam, uADStanError,
uADDatSManager, uADPhysIntf, uADDAptIntf, Data.DB, uADCompDataSet, uADCompClient, Vcl.StdCtrls,
Vcl.DBCtrls, Vcl.Mask, Vcl.ExtCtrls, Vcl.Grids, Vcl.DBGrids;
type
TForm1 = class(TForm)
Edit1: TEdit;
DataSource1: TDataSource;
ADMemTable1: TADMemTable;
ADMemTable1test: TStringField;
Button1: TButton;
DBEdit1: TDBEdit;
DBGrid1: TDBGrid;
DBNavigator1: TDBNavigator;
procedure FormCreate(Sender: TObject);
procedure Edit1Exit(Sender: TObject);
procedure FormDestroy(Sender: TObject);
private
FMyDataLink: TFieldDataLink;
procedure MyDataChange(Sender: TObject);
procedure MyUpdateData(Sender: TObject);
public
end;
var
Form1: TForm1;
implementation
{$R *.dfm}
procedure TForm1.FormCreate(Sender: TObject);
begin
AdMemTable1.CreateDataSet;
FMyDataLink := TFieldDataLink.Create();
FMyDataLink.DataSource := DataSource1;
FMyDataLink.FieldName := 'test';
FMyDataLink.OnDataChange := MyDataChange;
FMyDataLink.OnUpdateData := MyUpdateData;
AdMemTable1.Append;
AdMemTable1.FieldByName('test').AsString := 'my test';
AdMemTable1.Post;
end;
procedure TForm1.FormDestroy(Sender: TObject);
begin
FMyDataLink.OnDataChange := nil;
FMyDataLink.OnUpdateData := nil;
FMyDataLink.Free;
end;
procedure TForm1.Edit1Exit(Sender: TObject);
begin
if Edit1.Modified = true then
begin
FMyDataLink.Edit;
FMyDataLink.Modified;
end;
end;
procedure TForm1.MyDataChange(Sender: TObject);
begin
Edit1.Text := FMyDataLink.Field.AsString;
Edit1.Modified := false;
end;
procedure TForm1.MyUpdateData(Sender: TObject);
begin
FMyDataLink.Field.AsString := Edit1.Text
end;
end.

Answer 1

TFieldDataLink.Edit only sets the DataSource in editing state (just like DataSet.Edit). You do not need it here, but example usage could be:
procedure TMyCustomControl.DoPaste;
begin
FMyDataLink.Edit;
inherited DoPaste;
FMyDataLink.Modified;
end;
What you want instead on exit of the control is to update the record, if it is modified:
procedure TForm1.Edit1Exit(Sender: TObject);
begin
if Edit1.Modified then
try
FMyDataLink.UpdateRecord;
except
Edit1.SetFocus;
raise;
end;
end;
As for when TFieldDataLink.Modified should be called, that's when you have updated the field value:
procedure TForm1.MyUpdateData(Sender: TObject);
begin
FMyDataLink.Field.AsString := Edit1.Text;
FMyDataLink.Modified;
end;

Answer 2

It's an old question, but for those who are encountering the same problem,
you have to override the data-aware control's KeyPress method and call the FieldDataLink.Edit; after Inherited; if the Key is valid for the input (incl. del/c&p/bs/etc..).
At this point the current data is not yet modified. Calling .Edit later than this point is too late.