How do you load text from a file in Delphi? [closed] - delphi

Question

Closed. This question does not meet Stack Overflow guidelines. It is not currently accepting answers.
Questions asking for code must demonstrate a minimal understanding of the problem being solved. Include attempted solutions, why they didn't work, and the expected results. See also: Stack Overflow question checklist
Closed 9 years ago.
Improve this question
I have this code in Visual Basic that loads text from a file. I need to translate it into Delphi, but can't figure out how.
Open txtFile.Text For Binary As #1
file = Space(LOF(1))
Get #1, , file
Close #1
How do I get this code to work in Delphi?

Answer 1

If your Delphi is not too old, you can do this:
uses IOUtils;
...
S := TFile.ReadAllText('MyFileName.txt');
Don't invent your own solutions when the RTL provides something that's already good enough!

Answer 2

VB's LOF() returns a long integer that represents the length of a file. In this case, it's being used to allocate a string that is LOF spaces in size, and LOF() is returning the length of whatever filename is in txtFile.Text (which is probably an edit control).
Delphi doesn't need such techniques to simply load a text file into memory. The roughly equivalent code in Delphi if you're just wanting to get the file contents into a string:
function LoadTextFromFile(const FileName: string): string;
var
SL: TStringList;
begin
Result := '';
SL := TStringList.Create;
try
SL.LoadFromFile(FileName);
Result := SL.Text;
finally
SL.Free;
end;
end;
Using it:
var
MyText: string;
begin
MyText := LoadTextFromFile('C:\Temp\MyFile.txt');
// Do something with text
end;
It's even easier if you want to display the text for the user - just drop a TEdit, TMemo and a TButton on your form, double-click the button to create an OnClick event, and use code like this:
procedure TForm1.Button1Click(Sender: TObject);
begin
Memo1.Lines.LoadFromFile(Edit1.Text);
end;
For the purists out there, this is a close literal equivalent:
function GetStringFromFile(const FileName: string): AnsiString;
var
MS: TMemoryStream;
begin
Result := '';
MS := TMemoryStream.Create;
try
MS.LoadFromFile('D:\Temp\TestText.txt');
SetString(Result, PAnsiChar(MS.Memory), MS.Size);
finally
MS.Free;
end;
end;

Answer 3

You can use the TFileStream to open the file, specified in the TxtFile.text property
the '#1' is mean to be the file handle but it not neeed because you re using an OOP approach.
Open txtFile.Text For Binary As #1 mean to open the file not in text mode (as opening in the notepad) btu as binary so nothing could be translated to ascii characters. All will be read ad bytes not as characters
LOF(1) seems to return the length of the file (handle 1) and 'Space' will generate a string with the same number of space characters (#32) as the length of the files and assign it to variable 'file', then it will close the file handle.
So as an example:
var
FileContents: AnsiString; // Or an 'array of Byte' instead
Stream: TFileStream;
begin
Stream := TFileStream.Create(txtFile.Text, fmOpenRead);
try
SetLength(FileContents, Stream.Size);
if Length(FileContents) > 0 then
Stream.ReadBuffer(Pointer(FileContents)^, Stream.Size);
finally
Stream.Free;
end;
// Use FileContents as needed...
end;
Disclaimer notice:
I have not tested it yet; I'm not at my development computer right
now. So use it on your own risk.
What you have to determine is if you will read the data as bytes or
as characters.
The example assumes you're reading an ANSI text file
The example assumes you're reading a not so
large file, if it is large you have to read it in blocks.
The error handler is just an example how to manage an error
For more info, check TFileStream (and related classes) usage in the Delphi help documentation.