Delphi XE2: Loading .EXE icon into MenuItem at run-time - delphi

Question

At run-time, I want to load and show the main icon of a specific .EXE file in a specific MenuItem. When this is not possible for this specific .EXE file (e.g. due to access restrictions or similar), then the MenuItem icon should be set to a specific icon in a specific ImageList (e.g. MyMenuItem.ImageIndex := 7). How can this be done?

Answer 1

I think the simplest solution is to use ExtractIconEx. Here's a very simple example:
type
PHICON = ^HICON;
function ExtractIconEx(lpszFile: LPCWSTR; nIconIndex: Integer;
phiconLarge, phiconSmall: PHICON; nIcons: UINT): UINT; stdcall; external 'shell32.dll' name 'ExtractIconExW';
function GetSmallIconFromExecutableFile(const FileName: string): TIcon;
var
Icon: HICON;
ExtractedIconCount: UINT;
begin
Result := nil;
try
ExtractedIconCount := ExtractIconEx(
PChar(FileName),
0,
nil,
#Icon,
1
);
Win32Check(ExtractedIconCount=1);
Result := TIcon.Create;
Result.Handle := Icon;
except
Result.Free;
raise;
end;
end;

Answer 2

The icon associated with an executable file is the first one in the module. So you can extract it like this:
function EnumResNameProc(hModule: HMODULE; lpszType: LPCTSTR; lpszName: LPTSTR; lParam: LONG_PTR): BOOL; stdcall;
begin
HICON(Pointer(lParam)^) := LoadImage(
hModule,
lpszName,
IMAGE_ICON,
GetSystemMetrics(SM_CXSMICON),
GetSystemMetrics(SM_CYSMICON),
0
);
Result := False;
end;
function GetFirstSmallIcon(hmod: HMODULE): HICON;
begin
Result := 0;
EnumResourceNames(hmod, RT_GROUP_ICON, #EnumResNameProc, NativeInt(#Result));
end;
function GetSmallIconFromExecutableFile(const FileName: string): TIcon;
const
LOAD_LIBRARY_AS_IMAGE_RESOURCE = $00000020;
var
hmod: HMODULE;
Icon: HICON;
begin
Result := nil;
try
hmod := LoadLibraryEx(PChar(FileName), 0, LOAD_LIBRARY_AS_IMAGE_RESOURCE or LOAD_LIBRARY_AS_DATAFILE);
Win32Check(hmod<>0);
try
Icon := GetFirstSmallIcon(hmod);
if Icon<>0 then begin
Result := TIcon.Create;
Result.Handle := Icon;
end;
finally
FreeLibrary(hmod);
end;
except
Result.Free;
raise;
end;
end;