How to recover after ReWrite failure? - delphi

Question

I want to open a typed file as random access. This is done by setting the FileMode in fmOpenReadWrite. This requires the file to exist and I test whether the file exists and if not, ReWrite it and close it. See code below.
var fl: file of _some_record_type_;
fn: string;
AssignFile (fl, fn);
if not FileExists (fn) then
begin
ReWrite (fl);
CloseFile (fl); // Now an empty file exists
end; // if
FileMode := fmOpenReadWrite;
Reset (FTrack_File);
// ...further rad and write operations...
This works great except when fn is an illegal file name, for example when specifying a non-existing drive. It raises an exception at ReWrite. I cannot recover from the error by surrounding the ReWrite by try..except because any reference to that file or any other file raises an access violation exception. It appears that some condition has been set that prevents any file i/o.
Somebody knows how to handle this situation?

Answer 1

You can switch to using exceptions (with {$I+}), and then use try..except. (It's usually the default, unless you've unchecked I/O Checking in the Project Options dialog (Project->Options->Delphi Compiler->Compiling->Runtime Errors->I/O checking from the main menu).
If that box is unchecked, it sets the option {$I-}, which uses IOResult.
If you want to keep using IOResult, you'll need to check it after using the file functions. Checking it automatically resets the InOutRes variable to 0, clearing the previous error value.
AssignFile (fl, fn);
if not FileExists (fn) then
begin
ReWrite (fl);
if IOResult <> 0 then
// You've had an error.
CloseFile (fl); // Now an empty file exists
end; // if
IOResult can be found in the System unit.
You really should be moving away from the old style IO routines, BTW. They're ancient, and don't properly work with Unicode data. You can accomplish the same thing using a TFileStream, which would give you proper exception handling and support for Unicode. Here's a quick console app sample (tested with XP3 on Win 7):
program Project1;
{$APPTYPE CONSOLE}
{$R *.res}
uses
System.SysUtils, Classes, Windows;
type
TMyRec = record
anInt: Integer;
aBool: Boolean;
aByte: Byte;
end;
var
FS: TFileStream;
MyRec: TMyRec;
const
TheFile = 'C:\TempFiles\test.dat';
begin
MyRec.anInt := 12345;
MyRec.aBool := True;
MyRec.aByte := 128;
FS := TFileStream.Create(TheFile, fmCreate or fmOpenReadWrite);
try
FS.Write(MyRec, SizeOf(TMyRec));
// Clear the content and confirm it's been cleared
FillChar(MyRec, SizeOf(TMyRec), 0);
WriteLn('anInt: ', MyRec.anInt, ' aBool: ', MyRec.aBool, ' aByte: ', MyRec.aByte);
FS.Position := 0;
FS.Read(MyRec, SizeOf(TMyRec));
finally
FS.Free;
end;
// Confirm it's read back in properly
WriteLn('anInt: ', MyRec.anInt, ' aBool: ', MyRec.aBool, ' aByte: ', MyRec.aByte);
ReadLn;
end.