Enum a record in Delphi - delphi

Question

I have a record that contains a bunch of pointers that I would like to free.
type
FreeStruct = record
Addr1 : Pointer;
Addr2 : Pointer;
Addr3 : Pointer;
// ....
end;
So I would like to do something like:
var
MyStruct : FreeStruct:
begin
//MyStruct.Addr1 := ...;
for i := 0 to NumberOfFieldsInRecord do begin
VirtualFree (ValueOfFieldNumberOfMyStruct[I],0, MEM_RELEASE);
end;
end;
I heard there is something like RTII but I don't know how to use it properly with records and Delphi 7.

Answer 1

As far as I'm aware there are no methods to support record field iteration.
You can however play with the record structure on a low level basis (look here: http://www.delphigroups.info/2/18/295611.html)
Maybe you are better off restructuring your code so you will not need records for pointer storage.

Answer 2

There is no Rtti solution for your Delphi-7 version.
If you don't want to implement #ain's suggestion with an array of pointers inside a record,
here is a suggestion that uses a variant part in the record to accomplish a similar thing.
You can freely use myStruct.AddrX names for clarity in code, but also myStruct.allAddresses[X-1] to address the same field.
Type
FreeStruct =
record
intExample : Integer; // not in the variant part
case boolean of // Variant structure where the different parts overlap in memory
true : ( Addr1 : Pointer;
Addr2 : Pointer;
Addr3 : Pointer);
false : (allAddresses : array[0..2] of Pointer);
end;
procedure ClearFreeStruct( var AStruct : FreeStruct);
var
i: Integer;
begin
for i := 0 to High(AStruct.allAddresses) do
begin
// Dispose of allocated pointers
end;
end;
You can expand the structure with more pointers, but also include other fields (before the variant part).
It is possible to use an array of pointers within your record without giving up clarity.
By using an enumeration, it is possible to address each pointer with a relevant name.
Example: myStruct.Addr[peAddr1]
Type
PointerEnum = (peAddr1,peAddr2,peAddr3);
FreeStruct =
record
intExample : Integer;
Addr : array[PointerEnum] of Pointer;
end;
procedure ClearFreeStruct( var AStruct : FreeStruct);
var
pe : PointerEnum;
begin
for pe := Low(PointerEnum) to High(PointerEnum) do
begin
// Dispose(AStruct.Addr[pe]);
end;
end;