WMI values to array - delphi

Question

Good afternoon guys!
I'm currently developing a small system management tool, very much in a style similar to the Windows 8 Task Manager in Firemonkey (Delphi XE2). At the moment, i'm attempting to create the CPU Core Usage tiles using TPanels inside a TGridLayout. I've added all my panels at designtime until i get the actual functionality sorted.
My issue lies with outputting the data from WMI into an array. I've already had a working version not involving an array, but i'm having trouble creating something more dynamic and less likely to fall over in different configurations. Here's the current code that's not working entirely;
Procedure CoreUsage;
const
WbemUser ='';
WbemPassword ='';
WbemComputer ='localhost';
wbemFlagForwardOnly = $00000020;
var
FSWbemLocator : OLEVariant;
FWMIService : OLEVariant;
FWbemObjectSet: OLEVariant;
FWbemObject : OLEVariant;
oEnum : IEnumvariant;
iValue : LongWord;
i : Integer;
begin
try
CoInitialize(nil);
try
FSWbemLocator := CreateOleObject('WbemScripting.SWbemLocator');
FWMIService := FSWbemLocator.ConnectServer(WbemComputer, 'root\CIMV2', WbemUser, WbemPassword);
FWbemObjectSet:= FWMIService.ExecQuery('SELECT * FROM Win32_PerfFormattedData_Counters_ProcessorInformation WHERE NOT Name="_Total" AND NOT Name="0,_Total"',
'WQL',
wbemFlagForwardOnly);
oEnum := IUnknown(FWbemObjectSet._NewEnum) as IEnumVariant;
begin
if oEnum.Next(1, FWbemObject, iValue) = 0 then
begin
for i := 0 to 63 do
begin
CoreName[i] := FWbemObject.Name;
CoreUsage[i] := FWbemObject.PercentProcessorTime;
end;
end;
FWbemObject:=Unassigned;
end;
finally
CoUninitialize;
end;
end;
end;
CoreUsage and CoreName are both global variable arrays of length [0..63] of the relevant types (CoreName is of String, and CoreUsage is of Uint64). The problem with this is that it shows the same value in all the panels as opposed to a per-core basis (which is my intent). It's almost like it's not going through the 0..63, and instead just retrieving the first value only.
I'm essentially wanting to assign each one to a value within the array as that would allow me to easily read core-specific details without needing to hard code. In the code i had working completely on my development machine, i had to manually go through and use something like this;
if AnsiContainsText(FWbemObject.Name,'3') then
begin
CoreName[3] := FWbemObject.Name;
CoreUsage[3] := FWbemObject.PercentProcessorTime;
end
As you can see, it's hard coded to expect something but would be flaky in systems with 3 CPU's (in the above example). Obviously '3' was replaced with the appropriate array id, all the way from 0 to 63 (though 0 was looking for 0,0 specifically). The problem with this is that the CPU format is actually of x,y (where x is the CPU and y is the core). It's also not code that i'd be proud to use on the simple basis of it being unreliable. For example, the core name could potentially be 0,0 .. 0,7 and then 1,0 .. 1,7 for a system with 2 eight-core CPU's (16 logical cores).
Equally important, the code itself would have been a nightmare to maintain, but could have potentially been shortened down to a single for i := clause and using IntToStr. But the problem of making sure it works would still remain.
I'm sure there's a perfectly possible way to do this, but i can't figure it out. I did try using;
for VarArrayLowBound(FWbemObject.Name, 1) to VarArrayHighBound(FWbemObject.Name, 1) do
and
for VarArrayLowBound(FWbemObject.PercentProcessorTime, 1) to VarArrayHighBound(FWbemObject.PercentProcessorTime, 1) do
but alas, no such luck. Any ideas?

Answer 1

The problem is your loop here:
if oEnum.Next(1, FWbemObject, iValue) = 0 then
begin
for i := 0 to 63 do
begin
CoreName[i] := FWbemObject.Name;
CoreUsage[i] := FWbemObject.PercentProcessorTime;
end;
end;
You're simply reusing the same FwbemObject over and over again 64 times.
Try something more like:
var
iCurrObj: Integer;
...
iCurrObj := 0;
while oEnum.Next(1, FWbemObject, iValue) = 0 do
begin
CoreName[iCurrObj] := FWbemObject.Name;
CoreUsage[iCurrObj] := FWbemObject.PercentProcessorTime;
Inc(iCurrObj);
// Sanity check for future protection.
if i > High(CoreName) then
Break;
end;
Better yet, make it a function that actually lets you know how many items in the arrays it populated. Here's a working (tested) example. (Note: Your example in your question won't even compile despite the declaration of the two arrays, because your procedure name CoreUsage is the same name as your array CoreUsage.)
var
CoreName: array[0..63] of string;
CoreUsage: array[0..63] of Extended;
function CoreUse: Integer;
const
WbemUser ='';
WbemPassword ='';
WbemComputer ='localhost';
wbemFlagForwardOnly = $00000020;
var
FSWbemLocator : OLEVariant;
FWMIService : OLEVariant;
FWbemObjectSet: OLEVariant;
FWbemObject : OLEVariant;
oEnum : IEnumvariant;
iValue : LongWord;
i : Integer;
begin
i := 0;
CoInitialize(nil);
try
FSWbemLocator := CreateOleObject('WbemScripting.SWbemLocator');
FWMIService := FSWbemLocator.ConnectServer(WbemComputer, 'root\CIMV2', WbemUser, WbemPassword);
FWbemObjectSet:= FWMIService.ExecQuery('SELECT * FROM Win32_PerfFormattedData_Counters_ProcessorInformation WHERE NOT Name="_Total" AND NOT Name="0,_Total"', 'WQL', wbemFlagForwardOnly);
oEnum := IUnknown(FWbemObjectSet._NewEnum) as IEnumVariant;
while oEnum.Next(1, FWbemObject, iValue) = 0 do
begin
CoreName[i] := FWbemObject.Name;
CoreUsage[i] := FWbemObject.PercentProcessorTime;
Inc(i);
FWbemObject:=Unassigned;
end;
Result := i;
finally
CoUninitialize;
end;
end;